281413_de-DE

liliconcom

Ist es möglich, eine ColLIstBox zwei verschiedenen Datentabellen zuzuordnen?

Hallo zusammen,

 

Ich habe ein Tool, das auf zwei verschiedenen Datentabellen basiert.

Auf der Startoberfläche muss der Benutzer einige Spalten angeben, die aus der ersten Tabelle stammen, einige Spalten, die aus den zweiten Tabellen stammen, sowie einige Spalten, die entweder in der ersten oder in der zweiten Tabelle enthalten sein können.

Hier ist ein kleines Beispiel, um mein Problem zu reproduzieren:

 

dt1 = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt2 = Open( "$SAMPLE_DATA/Cities.jmp" );
new window("Test",
 hlistbox (
  panel box ("Table 1",
   hlist box(
    collistbox(data table(dt1),all),
    vlist box(
     text box("Select a variable from table 1"),
     CL1 = collistbox(data table(dt1),nlines(1),maxitems(1))
    )
   )
  ),
  panel box ("Table 2",
   hlist box(
    collistbox(data table(dt2),all),
    vlist box(
     text box("Select a variable from table 2"),
     CL2 = collistbox(data table(dt2),nlines(1),maxitems(1))
    )
   )
  ),
  panel box ("Last variable",
   vlist box(
    text box("Select a variable from table 1 or table 2"),
    CL3 = collistbox(maxitems(1),nlines(1))
   )
  )
 )
)

In CL3 möchte ich entweder eine Spalte der ersten Tabelle oder eine Spalte der zweiten Tabelle einfügen können. Ich bin mir nicht sicher, ob dies mit einem ColListBox-Objekt möglich ist. Weißt du sonst, ob es einen anderen Weg gibt, das zu tun?

 

Vielen Dank im Voraus für Ihre Hilfe!

 

 

SkriptingBetreff: Ist es möglich, eine ColLIstBox zwei verschiedenen Datentabellen zuzuordnen?

Hier ist ein kleiner Trick, den ich in der Vergangenheit für andere Probleme verwendet habe, aber er funktioniert gut.  Ich habe Ihren Code geändert, um eine neue private Datentabelle zu erstellen, die alle Spalten enthält, aber keine Daten.  Hier können Sie Spalten aus einem der Spaltenlistenfelder () auswählen.

names default to here(1);

dt1 = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt2 = Open( "$SAMPLE_DATA/Cities.jmp" );
dt3 = dt1 << concatenate(private,dt2);
dt3 << delete rows(index(1,nrows(dt3)));
nw = new window("Test",
 hlistbox (
  panel box ("Table 1",
   hlist box(
    collistbox(data table(dt1),all),
    vlist box(
     text box("Select a variable from table 1"),
     CL1 = collistbox(data table(dt1),nlines(1),maxitems(1))
    )
   )
  ),
  panel box ("Table 2",
   hlist box(
    collistbox(data table(dt2),all),
    vlist box(
     text box("Select a variable from table 2"),
     CL2 = collistbox(data table(dt2),nlines(1),maxitems(1))
    )
   )
  ),
  panel box ("Last variable",
   vlist box(
    text box("Select a variable from table 1 or table 2"),
    CL3 = collistbox(data table(dt3),maxitems(1),nlines(1))
   )
  )
 )
);

nw << on close( close(dt3,nosave));

Betreff: Ist es möglich, eine ColLIstBox zwei verschiedenen Datentabellen zuzuordnen?

Vielen Dank @ txnelson Das ist wirklich ein schöner Trick! Es kann einige Anpassungen für bestimmte Fälle erfordern, sonst denke ich, dass es genau das ist, wonach ich gesucht habe!