277047_fr-FR

liliconcom

créer et remplir une nouvelle colonne avec des données définies par l'utilisateur

Salut,

 

Je suis un utilisateur inexpérimenté des scripts JMP, j'ai besoin d'aide pour ajouter une nouvelle colonne, et les données de la nouvelle colonne seront définies par l'utilisateur avec un nombre fixe. Cela signifie que, chaque fois que j'exécute le code, il devrait demander le nombre intéressé de remplissage dans une nouvelle colonne. En fait, j'ai un nombre différent et des tâches différentes (pour la nouvelle colonne) à remplir dans le même tableau de données.

 

 

ScriptingRe: création et remplissage d'une nouvelle colonne avec des données définies par l'utilisateur

Si je comprends votre demande, il semble que vous souhaitiez à la fois être l'utilisateur d'une valeur, puis utiliser cette valeur dans une formule.  Cela pourrait vous aider à démarrer:

 

//Make sure variables names defined here do not interfere with other scripts
Names default to here(1);

//start by opening a data table.  Instead of this, you could just use
// dt = current data table();
dt = Open("$Sample_Data/iris.jmp");

dt << New Script(
 "New Column",
 //Open a new window which...
 win = New Window ( "Create a column",
  Show Menu( 0 ),
  Show Toolbars( 0 ),
  v list box(
   Text Box( "Add a new column."),
   Spacer box( Size( 20,20 ) ),
   
   //asks the user for a column name...
   Text Box("Enter a column name"),
   tebName =  Text Edit Box( "Column 1", Set Width( 200 ) ),
   Spacer box( Size( 10,10 ) ),
   
   
   //and a value...
   Text Box("Enter a value in the column"),
   nebValue = Number Edit Box( 0 ),
   Spacer box( Size( 10,10 ) ),

   H list box(
    //and includeds a button with a script that creates the column...
    Button Box( "Create A Column",
    
     //Use Eval, Eval Expr, and Expr to put the RESULT of the expression "nebValue << Get" into the formula
     //instead of the expression itself
     Names default to here( 1 );
     dt = current data table();
     Eval( Eval Expr(
      dt << New Column( tebName << Get Text, Numeric, "Continuous", Format("Best", 12), Formula( Expr( nebValue << Get ) ) )
     ) )
    ),

    //and another button to close the window.
    Button Box( "Close",
     win << Close Window
    )
   )
  )
 );
);

Re: création et remplissage d'une nouvelle colonne avec des données définies par l'utilisateur

Salut,

 

Je vous remercie de votre aide et cela m'aide principalement à terminer mes scripts. En fait, mes tâches et ma mission concernent la nécessité d'extraire le fichier csv qui ne comprenait pas de données complètes et de le compléter avec des données variables dépend de mon projet. Il semble que votre code m'aide davantage, alors maintenant, je dois réfléchir à la façon de combiner depuis la phase initiale jusqu'à ce que j'obtienne le graphique en utilisant uniquement du code unique. Peut-être que cela peut être fait et que vous avez également besoin d'un expert dans ce groupe communautaire pour vous conseiller. Merci beaucoup.