274907_de-DE

liliconcom

For-Schleife zum Anzeigen des Variabilitätsdiagramms mit Zeilenlegende

Ich möchte mehrere Variabilitätsdiagramme mit der Anzeige einer Zeilenlegende auf der rechten Seite zeichnen. Wenn Sie dies jedoch mit der for-Schleife tun, kann die Zeilenlegende nicht angezeigt werden. Kann mir bitte jemand einen Rat geben?

Das Diagramm, das ich für alle Parameter haben wollte.

Stattdessen erhalte ich nur die Grafik unten mit der Zeilenlegendenanzeige auf der rechten Seite.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );


/* Obtain a list of numeric/continuous column names as strings */
colList = dt << Get Column Names( Continuous, String );


For( i = 2, i <= Nitems( colList ), i++,
	
	Variability Chart(
		Y( colList[i] ),
		X( :lot_id, :wafer ),
		Connect Cell Means( 1 ),
		Std Dev Chart( 0 ),
		SendToReport(
			Dispatch(
				{},
				"Variability Chart for " || colList[i],
				OutlineBox,
				{Set Title( "GROUP 1 Variability Chart for " || colList[i] )}
			),
			Dispatch(
				{"Variability Chart for " || colList[i]},
				"Variability Chart",
				FrameBox,
				{Row Legend(
					lot_id,
					Color( 1 ),
					Color Theme( "JMP Default" ),
					Marker( 1 ),
					Marker Theme( "Standard" ),
					Continuous Scale( 0 ),
					Reverse Scale( 0 ),
					Excluded Rows( 0 )
				)}
			)
		)
	);

);

MassenanpassungBetreff: For-Schleife zum Anzeigen des Variabilitätsdiagramms mit Zeilenlegende

Hallo Tom,

 

Das Gleiche gilt für Jims Feststellung: Es dauert lange, zu rennen und zeitweise hängen zu bleiben. Aber ich habe es einmal zum Laufen gebracht.

Betreff: For-Schleife zum Anzeigen des Variabilitätsdiagramms mit Zeilenlegende

Wenn ich diesen Code ausführe, scheint er in einer Schleife festzustecken.Auf jeden Fall scheint JMP zu hängen.Ich verwende Version 13.2.1

Betreff: For-Schleife zum Anzeigen des Variabilitätsdiagramms mit Zeilenlegende

Hallo,

Bitte führen Sie den folgenden Code aus.

Ich hoffe, es funktioniert.

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );


/* Obtain a list of numeric/continuous column names as strings */
colList = dt << Get Column Names( Continuous, String );
win = New Window("Example");

For( i = 2, i <= Nitems( colList ), i++,
 
 win << Append(varobj = Variability Chart(
  Y( Column(dt,colList[i]) ),
  X( :lot_id, :wafer ),
  Connect Cell Means( 1 ),Std Dev Chart( 0 )
 ));
 (varobj << report)[OutlineBox(1)] << set Title("GROUP 1 " || ((varobj << report)[OutlineBox(1)] << Get Title));
 (varobj << report)[FrameBox(1)] << Row Legend(Column(dt,"lot_id"),Color( 1 ),Marker( 1 ));
);