274907_fr-FR

liliconcom

Boucle For pour afficher le tracé de variabilité avec la légende des lignes

Je souhaite tracer plusieurs tracés de variabilité avec l'affichage de la légende des lignes à droite. Mais lorsque vous faites cela avec la boucle for, la légende de la ligne ne peut pas s'afficher. quelqu'un peut-il me conseiller s'il vous plaît ?

le graphique que je voulais avoir pour chaque paramètre.

au lieu de cela, je n'obtiens que le graphique ci-dessous avec l'affichage de la légende des lignes à droite.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );


/* Obtain a list of numeric/continuous column names as strings */
colList = dt << Get Column Names( Continuous, String );


For( i = 2, i <= Nitems( colList ), i++,
	
	Variability Chart(
		Y( colList[i] ),
		X( :lot_id, :wafer ),
		Connect Cell Means( 1 ),
		Std Dev Chart( 0 ),
		SendToReport(
			Dispatch(
				{},
				"Variability Chart for " || colList[i],
				OutlineBox,
				{Set Title( "GROUP 1 Variability Chart for " || colList[i] )}
			),
			Dispatch(
				{"Variability Chart for " || colList[i]},
				"Variability Chart",
				FrameBox,
				{Row Legend(
					lot_id,
					Color( 1 ),
					Color Theme( "JMP Default" ),
					Marker( 1 ),
					Marker Theme( "Standard" ),
					Continuous Scale( 0 ),
					Reverse Scale( 0 ),
					Excluded Rows( 0 )
				)}
			)
		)
	);

);

Personnalisation de masseRe : Boucle pour afficher le tracé de la variabilité avec la légende de la ligne

Bonjour Tom,

 

Identique à la découverte de Jim, il faut beaucoup de temps pour courir et se bloquer par intermittence. Mais je l'ai fait fonctionner une fois cependant.

Re : Boucle pour afficher le tracé de la variabilité avec la légende de la ligne

Lorsque j'exécute ce code, il semble être bloqué dans une boucle.Quoi qu'il en soit, JMP semble se bloquer.J'utilise la version 13.2.1

Re : Boucle pour afficher le tracé de la variabilité avec la légende de la ligne

Salut,

veuillez exécuter le code suivant.

J'espère qu'il fera l'affaire.

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );


/* Obtain a list of numeric/continuous column names as strings */
colList = dt << Get Column Names( Continuous, String );
win = New Window("Example");

For( i = 2, i <= Nitems( colList ), i++,
 
 win << Append(varobj = Variability Chart(
  Y( Column(dt,colList[i]) ),
  X( :lot_id, :wafer ),
  Connect Cell Means( 1 ),Std Dev Chart( 0 )
 ));
 (varobj << report)[OutlineBox(1)] << set Title("GROUP 1 " || ((varobj << report)[OutlineBox(1)] << Get Title));
 (varobj << report)[FrameBox(1)] << Row Legend(Column(dt,"lot_id"),Color( 1 ),Marker( 1 ));
);