270873_es-ES

liliconcom

¿Puedes ayudar a hacer múltiples diagramas de dispersión en una tabla usando script?

Hola a todos.

 

Puedo imprimir múltiples diagramas de dispersión en una tabla usando este script que hice.

 

Names Default To Here( 1 );
dt = Open( "$Sample_Data/Big Class.jmp" );
dt = Current Data Table();

For( i = 4, i <= N Cols( dt ), i++,
 Column( dt, i ) << data type( numeric );
 Column( dt, i ) << set modeling type( continuous );
);
address = Current Data Table();

Scatterplot Matrix(
 Y(
  :Column(address, 4),
  :Column(address, 5) 
   
  ),
 X( :Column(address, 2) ),
 Fit Line( 0 ),
 SendToReport
 ( 
  Dispatch
  ( 
  {}, 
  "1100", 
  ScaleBox, 
     {
     Add Ref Line( :Column(address, 4)[2], "Solid", "Medium Dark Blue", "LSL", 1 ),
     Add Ref Line( :Column(address, 4)[3], "Solid", "Medium Dark Blue", "USL", 1 )
     } 
  ),
  Dispatch
  ( 
  {}, 
  "1101", 
  ScaleBox, 
     {
     Add Ref Line( :Column(address, 5)[2], "Solid", "Medium Dark Blue", "LSL", 1 ),
     Add Ref Line( :Column(address, 5)[3], "Solid", "Medium Dark Blue", "USL", 1 )
     } 
  ),
   Dispatch(
   {},
   "Scatterplot Matrix Plot",
   FrameBox,
   {Frame Size( 600, 200 )}
  ),
 )
);

 

 

Traté de usar la función [for] como el script a continuación.

 

Names Default To Here( 1 );
dt = Open( "$Sample_Data/Big Class.jmp" );
dt = Current Data Table();

For( i = 4, i <= N Cols( dt ), i++, 
 Column( dt, i ) << data type( numeric );
 Column( dt, i ) << set modeling type( continuous );
);
address = Current Data Table();

For( i = 4, i <= 5, i++,
Scatterplot Matrix(
 Y(
  :Column(address, i) 
  ),
 X( :Column(address, 2) ),
 Fit Line( 0 ),
 SendToReport
 ( 
  Dispatch
  ( 
  {}, 
  "1100", 
  ScaleBox, 
     {
     Add Ref Line( :Column(address, i)[2], "Solid", "Medium Dark Blue", "LSL", 1 ),
     Add Ref Line( :Column(address, i)[3], "Solid", "Medium Dark Blue", "USL", 1 )
     } 
  ),

   Dispatch(
   {},
   "Scatterplot Matrix Plot",
   FrameBox(i),
   {Frame Size( 600, 200 )}
  )
 )
);
);

 

 

 

sin embargo, el guión hizo gráficos entre sí.

 

 

Ayúdame a hacer una dispersión múltiple en una tabla usando la función [for] ... T ^ T

 

AnalíticaTabla de datosScriptingRe: ¿Puedes ayudar a hacer múltiples diagramas de dispersión en una tabla usando script?

Su propuesta de dónde desea usar un bucle For (), realmente no es lo que se necesita.  Si te entiendo correctamente, lo que quieres es producir una matriz de diagrama de dispersión con múltiples columnas Y y una sola columna x.  Para hacer esto, no necesita recorrer el código del diagrama de dispersión, todo lo que realmente necesita hacer es crear una lista de columnas que desee para las Y, y luego conectar esa lista.  Ahora, con respecto a la adición de límites de especificación a cada uno de los gráficos, le sugiero que cree una tabla independiente con los límites requeridos y luego copie los límites en la tabla de datos.  luego, cuando se procesan los datos, los límites se colocarán automáticamente en las distintas matrices.

Names Default To Here( 1 );
dt = Open( "$Sample_Data/Blood pressure.jmp" );

// Create a list of all of the columns one wants for Y values in the 
// scatterplot matrix
colNamesList = dt << get column names( continuous );

// Here is the limits table.  This can be just a saved data table that is
// opened in the script.  It does not have to be a table built in a script
dtLimits = New Table( "Limits",
 Add Rows( 9 ),
 New Column( "Variable",
  Character,
  "Nominal",
  Set Values( {"BP 8M", "BP 12M", "BP 6M", "BP 8W", "BP 12W", "BP 6W", "BP 8F", "BP 12F", "BP 6F"} )
 ),
 New Column( "LSL",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [175, 175, 175, 171, 173, 171, 172, 174, 172] )
 ),
 New Column( "USL",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [180, 185, 185, 187, 190, 180, 185, 188, 186] )
 ),
 New Column( "Target", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., ., ., ., ., ., ., ., .] ) ),
 New Column( "Show Limits",
  Numeric,
  "Nominal",
  Format( "Best", 12 ),
  Set Values( [1, 1, 1, 1, 1, 1, 1, 1, 1] )
 )
);

// Add the limits from the limits data table to the data table with the
// data values in it
For( i = 1, i <= N Rows( dtLimits ), i++,
 Eval(
  Substitute(
    Expr(
     Column( dt, dtLimits:Variable[i] ) << set property(
      "spec limits",
      {LSL( __LSL__ ), USL( __USL__ ), show limits( 1 )}
     )
    ),
   Expr( __LSL__ ), dtLimits:LSL[i],
   Expr( __USL__ ), dtLimits:USL[i]
  )
 )
);

// Create the Scatterplot Matrix
dt << Scatterplot Matrix(
 Y(
  Eval( colNamesList ) 
   
 ),
 X( :Column( dt, 2 ) ),
 Fit Line( 0 ),
 SendToReport( Dispatch( {}, "Scatterplot Matrix Plot", FrameBox, {Frame Size( 600, 200 )} ), )
);

Re: ¿Puedes ayudar a hacer múltiples diagramas de dispersión en una tabla usando script?

Tu consejo es muy útil para mí.

¡Gracias Dr. Jim!