270873_it-IT

liliconcom

Potete aiutarmi a trasformare più grafici a dispersione in una tabella usando lo script?

Ciao a tutti.

 

Posso stampare più grafici a dispersione in una tabella usando questo script che ho creato.

 

Names Default To Here( 1 );
dt = Open( "$Sample_Data/Big Class.jmp" );
dt = Current Data Table();

For( i = 4, i <= N Cols( dt ), i++,
 Column( dt, i ) << data type( numeric );
 Column( dt, i ) << set modeling type( continuous );
);
address = Current Data Table();

Scatterplot Matrix(
 Y(
  :Column(address, 4),
  :Column(address, 5) 
   
  ),
 X( :Column(address, 2) ),
 Fit Line( 0 ),
 SendToReport
 ( 
  Dispatch
  ( 
  {}, 
  "1100", 
  ScaleBox, 
     {
     Add Ref Line( :Column(address, 4)[2], "Solid", "Medium Dark Blue", "LSL", 1 ),
     Add Ref Line( :Column(address, 4)[3], "Solid", "Medium Dark Blue", "USL", 1 )
     } 
  ),
  Dispatch
  ( 
  {}, 
  "1101", 
  ScaleBox, 
     {
     Add Ref Line( :Column(address, 5)[2], "Solid", "Medium Dark Blue", "LSL", 1 ),
     Add Ref Line( :Column(address, 5)[3], "Solid", "Medium Dark Blue", "USL", 1 )
     } 
  ),
   Dispatch(
   {},
   "Scatterplot Matrix Plot",
   FrameBox,
   {Frame Size( 600, 200 )}
  ),
 )
);

 

 

Ho provato a usare la funzione [per] come lo script seguente.

 

Names Default To Here( 1 );
dt = Open( "$Sample_Data/Big Class.jmp" );
dt = Current Data Table();

For( i = 4, i <= N Cols( dt ), i++, 
 Column( dt, i ) << data type( numeric );
 Column( dt, i ) << set modeling type( continuous );
);
address = Current Data Table();

For( i = 4, i <= 5, i++,
Scatterplot Matrix(
 Y(
  :Column(address, i) 
  ),
 X( :Column(address, 2) ),
 Fit Line( 0 ),
 SendToReport
 ( 
  Dispatch
  ( 
  {}, 
  "1100", 
  ScaleBox, 
     {
     Add Ref Line( :Column(address, i)[2], "Solid", "Medium Dark Blue", "LSL", 1 ),
     Add Ref Line( :Column(address, i)[3], "Solid", "Medium Dark Blue", "USL", 1 )
     } 
  ),

   Dispatch(
   {},
   "Scatterplot Matrix Plot",
   FrameBox(i),
   {Frame Size( 600, 200 )}
  )
 )
);
);

 

 

 

tuttavia, la sceneggiatura si è fatta un grafico a vicenda.

 

 

Aiutatemi a creare una dispersione multipla in una tabella usando la funzione [per] ... T ^ T

 

analiticaTabella datiScriptingRi: Puoi aiutare a creare più grafici a dispersione in una tabella usando lo script?

La tua proposta per dove vuoi usare un ciclo For (), in realtà non è ciò che è necessario.  Se ti sto capendo correttamente, quello che vuoi è produrre una matrice scatterplot con più colonne Y e una singola colonna x.  Per fare ciò, non è necessario scorrere il codice scatterplot, tutto quello che devi fare è creare un elenco di colonne che desideri per Y e quindi collegarlo.  Ora riguardo all'aggiunta di limiti di specifica a ciascuno dei grafici, suggerisco di creare una tabella indipendente con i limiti richiesti e quindi di copiarli nella tabella di dati.  quindi quando i dati vengono elaborati, i limiti verranno automaticamente applicati alle varie matrici.

Names Default To Here( 1 );
dt = Open( "$Sample_Data/Blood pressure.jmp" );

// Create a list of all of the columns one wants for Y values in the 
// scatterplot matrix
colNamesList = dt << get column names( continuous );

// Here is the limits table.  This can be just a saved data table that is
// opened in the script.  It does not have to be a table built in a script
dtLimits = New Table( "Limits",
 Add Rows( 9 ),
 New Column( "Variable",
  Character,
  "Nominal",
  Set Values( {"BP 8M", "BP 12M", "BP 6M", "BP 8W", "BP 12W", "BP 6W", "BP 8F", "BP 12F", "BP 6F"} )
 ),
 New Column( "LSL",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [175, 175, 175, 171, 173, 171, 172, 174, 172] )
 ),
 New Column( "USL",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [180, 185, 185, 187, 190, 180, 185, 188, 186] )
 ),
 New Column( "Target", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., ., ., ., ., ., ., ., .] ) ),
 New Column( "Show Limits",
  Numeric,
  "Nominal",
  Format( "Best", 12 ),
  Set Values( [1, 1, 1, 1, 1, 1, 1, 1, 1] )
 )
);

// Add the limits from the limits data table to the data table with the
// data values in it
For( i = 1, i <= N Rows( dtLimits ), i++,
 Eval(
  Substitute(
    Expr(
     Column( dt, dtLimits:Variable[i] ) << set property(
      "spec limits",
      {LSL( __LSL__ ), USL( __USL__ ), show limits( 1 )}
     )
    ),
   Expr( __LSL__ ), dtLimits:LSL[i],
   Expr( __USL__ ), dtLimits:USL[i]
  )
 )
);

// Create the Scatterplot Matrix
dt << Scatterplot Matrix(
 Y(
  Eval( colNamesList ) 
   
 ),
 X( :Column( dt, 2 ) ),
 Fit Line( 0 ),
 SendToReport( Dispatch( {}, "Scatterplot Matrix Plot", FrameBox, {Frame Size( 600, 200 )} ), )
);

Ri: Puoi aiutare a creare più grafici a dispersione in una tabella usando lo script?

Il tuo consiglio è molto utile per me.

Grazie, dottor Jim!