269771_it-IT

liliconcom

Ri: FOR () Loop Script non funziona

Ecco un semplice script, che crea una colonna: Time e quindi genera ciò che credo che tu stia specificando dovrebbe essere il tuo: Esegui colonna.  Genero la colonna: Esegui utilizzando 3 metodi diversi.  Puoi leggere tutto questo nella Guida agli script

     Guida ==> Libreria di documentazione JMP ... ………. Guida alla scrittura

Names Default To Here( 1 );
dt = New Table( "Example",
 add rows( 20 ),
 New Column( "Time", formula( Random Uniform( .5, 1.5 ) ) )
);

dt << New Column( "Run1",
 "numeric",
 "ordinal",
 formula( If( :Time < 1, Row(), Row() + 1 ) )
);
 
dt << New Column( "Run2", numeric, ordinal );

For( i = 1, i <= N Rows( dt ), i++,
 If( :Time[i] < 1,
  :Run2[i] = i,
  :Run2[i] = i + 1
 )
);

dt << New Column( "Run3", numeric, ordinal );

For Each Row(
 If( :Time < 1,
  :Run3 = Row(),
  :Run3 = Row() + 1
 )
);

FOR () Loop Script non funziona

Voglio scrivere un valore di sequenziamento in una nuova colonna dopo aver verificato una condizione (valore temporale) o un set fisso di righe.

Belo JMP script il mio script di seguito crea una colonna di valore null.

Names Default To Here(1);
ROW = N ROW();
Run= New Column("Run", "numeric","ordinal");
n=1;
For(i = 1,
i<=ROW, i++,
If(:Time<1,i,i+1)
)

 

Qualsiasi consiglio da parte della comunità sarà molto apprezzato.

 

 

ScriptingRi: FOR () Loop Script non funziona

@txnelson 

Grazie per la tua pronta guida. Script parzialmente funzionato. Il mio tempo è in sequenza e la logica sta assegnando un nuovo numero a ogni riga.

Per semplificare, come faccio a creare una colonna che conta le righe fino a 1 secondo o 10 righe e assegna un numero e ripete il processo fino alla fine della tabella. 

 

Grazie per l'aiuto!

 

Ri: FOR () Loop Script non funziona

Credo che l'esempio qui sotto faccia quello che vuoi

Names Default To Here( 1 );
dt = New Table( "Example",
 add rows( 50 ),
 New Column( "Time",
  formula( Today() + Random Uniform( 10, 20. ) ),
  Format( "h:m:s", 11, 2 )
 )
);
dt << run formulas;
dt:time << delete formula;

dt << sort( by( :time ), order( ascending ), replace table( 1 ) );

dt << New Column( "Sequence",
 formula(
  If( Row() == 1,
   start = :time;
   count = 0;
  );
 
  If( count >= 10 | :Time - Start > 1,
   start = :time;
   count = 0;
  );
  count = count + 1;
 )
);