267893_ko-KR

liliconcom

새 열의 데이터 유형 설정

안녕하세요, 어떻게 조건부 및 프로그래밍 방식으로 새 열의 데이터 유형을 설정할 수 있습니까? 숫자/문자를 다루는 해결 방법이 있으며 다른 유형으로 확장할 수 있지만 아래 방법('작동하지 않음'으로 표시)을 작동시키려고 합니다. 로그는 유형 변수를 인식하지 못한다고 표시합니다. parse()와 같은 몇 가지를 시도했지만 지금까지 성공하지 못했습니다.

Names Default To Here( 1 );

dt = open( "$SAMPLE_DATA\Big Class.jmp");

colType = column(dtData,"Name") << get data type;

// doesn't work, error on colType
dt << add multiple columns("New Column", 1, After("Name"), colType);

// works
dt << add multiple columns("New Column", 1, After("Name"), Numeric);
if(colType == "Character", column(dt, "New Column") << data type ("Character"));

 

 

 

Re: 새 열의 데이터 유형 설정

짐은 그것을 못 박았다. 다음은 코드에 더 잘 맞는 문장이 있는 경우에 대비하여 해당 문장을 구성하는 몇 가지 방법입니다.

 

Eval Insert, Eval Expr, Parse 및 Substitute를 사용하여 한 표현식을 다른 표현식에 삽입

Re: 새 열의 데이터 유형 설정

여러 열 추가는 명령문의 실제 실행 전에 구문 분석을 허용하지 않는 것으로 보입니다.따라서 여러 열 추가로 표시되는 내용은 실행을 위해 JMP에 제공하기 전에 완전히 구체화되어야 합니다.다음은 몇 가지 방법입니다.

Names Default To Here( 1 );
dt = Current Data Table();
coltype = "character";
Eval(
 Parse(
  Eval Insert(
   "dt << add multiple columns(\!"New Column\!", 1, After(\!"Name\!"), ^colType^)"
  )
 )
);

// or

Eval(
 Substitute(
   Expr(
    dt << add multiple columns(
     "New Column",
     1,
     After( "Name" ),
     __type__
    )
   ),
  Expr( __type__ ), colType));