tablebox question

bumimeku

Hi

 

I want to make a tablebox that one of it column each cell can have a value of "Yes" or "No"

thought of using a combobox for it

try using the following code with no success

 

New Window( "Bla Bla",
	tb = Table Box( c1 = String Col Box( "Bla Bla", {cb = Combo Box( {"Yes", "No"} ) << get selected} ) )
)

 

any idea?

 

 

 

pmroz

You can achieve this using col boxes.  Mentioned in the presentation by myself and @Justin.chilton.

 

Here's some sample code that shows a variety of things you can do with col boxes.

// Col Box Examples
nw = New Window( "Mountains",
	tb = Table Box(
		sb = String Col Box( "Mountain",
			{"K2", "Delphi", "Kilimanjaro", "Grand Teton"}),
// Text boxes of different colors
		cc = col box("PT Name", 
			tb1 = textbox("Hello"),
			tb2 = textbox("World"),
			tb3 = textbox("Fubar"),
			tb4 = textbox("Geronimo")),
		nb = Number Col Box( "Elevation (meters)",
			{8611, 681, 5895, 4199}),
// Checkboxes, no header
		cb1 = checkbox({"", "", "", ""}),
// Checkboxes, with a header
		cb2 = col box("Yes/No?",
			cba = checkbox(""),
			cbb = checkbox(""),
			cbc = checkbox(""),
			cbd = checkbox("")),

// Comboboxes
		cb2 = col box("Response?",
			cmb1 = combobox({"Yes", "No"}),
			cmb2 = combobox({"Yes", "No"}),
			cmb3 = combobox({"Yes", "No"}),
			cmb4 = combobox({"Yes", "No"})),

// Button boxes
		bb = col box("Comment",
			bb1 = buttonbox("", print("First Button Action")),
			bb2 = buttonbox("", print("Second Button Action")),
			bb3 = buttonbox("", print("Third Button Action")),
			bb4 = buttonbox("", print("Fourth Button Action")),
		),
	),
	panelbox("Actions",
		hlistbox(
			button box("Cancel", nw << close window),
			button box("OK", 
				yn1 = cb1 << get(1); yn2 = cb1 << get(2);
				yn3 = cb1 << get(3); yn4 = cb1 << get(4);
				yna = cba << get(1); ynb = cbb << get(1);
				ync = cbc << get(1); ynd = cbd << get(1);
				print(char(yn1) || char(yn2) || char(yn3) || char(yn4));
				print(char(yna) || char(ynb) || char(ync) || char(ynd));
				nw << close window;
			),
		),
	),
);
tb << set underline headings(1) << set column borders(1) << Set Shade Alternate Rows(1);

nb << Set Conditional Format("Alert Rule");

// Set color and style of text boxes
tb1 << font color("Red") << set font style("Bold");
tb2 << font color("Blue");
tb3 << font color("Green");
tb4 << font color("Orange") << set font style("Bold");

// Set icon for button boxes
bb1 << set icon("SASLog");
bb2 << set icon("SASLog");
bb3 << set icon("SASLog");
bb4 << set icon("SASLog");