262258_ja-JP

liliconcom

1つのウィンドウで2つのグラフを組み合わせる

こんにちは、

私は2つのグラフを作成しました。それぞれに列切り替えがあり、以下のスクリプトを使用して1つのウィンドウに追加しました。

BoxPlot = LBSelectSplit << Graph Builder(
 Size( 1199, 762 ),
 Show Control Panel( 0 ),
 Show Legend( 0 ),
 Variables(
  X(
   :Visit Name,
   Order By( :Visit Number, Ascending, Order Statistic( "Mean" ) )
  ),
  Y( :Alanine Aminotransferase )
 ),
 Elements( Box Plot( X, Y, Legend( 6 ) ) ),
 Column Switcher(
  :Alanine Aminotransferase,
  {:Alanine Aminotransferase, :Albumin, :Alkaline Phosphatase, :Amylase,
  :Aspartate Aminotransferase, :Bilirubin, :C Reactive Protein, :Calcitonin,
  :Calcium, :Cholesterol, :Creatine Kinase, :Creatinine, :Eosinophils,
  :Erythrocytes, :Gamma Glutamyl Transferase,
  :Name( "Glomerular Filtration Rate, Estimated" ), :HDL Cholesterol,
  :Hematocrit, :Hemoglobin, :Hemoglobin A1C, :LDL Cholesterol, :Leukocytes,
  :Lipase, :Lymphocytes, :Monocytes, :Neutrophils, :Platelets, :Potassium,
  :Sodium, :Triglycerides, :Urea, :VLDL Cholesterol}
 )
);


MeanPlot = LBSelectSplit << Graph Builder(
 Size( 1181, 745 ),
 Show Control Panel( 0 ),
 Show Legend( 0 ),
 Fit to Window( "Maintain Aspect Ratio" ),
 Variables(
  X(
   :Visit Name,
   Order By( :Visit Number, Ascending, Order Statistic( "Mean" ) )
  ),
  Y( :Alanine Aminotransferase )
 ),
 Elements( Line( X, Y, Legend( 6 ), Error Bars( "Standard Error" ) ) ),
 Column Switcher(
  :Alanine Aminotransferase,
  {:Alanine Aminotransferase, :Albumin, :Alkaline Phosphatase, :Amylase,
  :Aspartate Aminotransferase, :Bilirubin, :C Reactive Protein, :Calcitonin,
  :Calcium, :Cholesterol, :Creatine Kinase, :Creatinine, :Eosinophils,
  :Erythrocytes, :Gamma Glutamyl Transferase,
  :Name( "Glomerular Filtration Rate, Estimated" ), :HDL Cholesterol,
  :Hematocrit, :Hemoglobin, :Hemoglobin A1C, :LDL Cholesterol, :Leukocytes,
  :Lipase, :Lymphocytes, :Monocytes, :Neutrophils, :Platelets, :Potassium,
  :Sodium, :Triglycerides, :Urea, :VLDL Cholesterol}
 )
);

New Window("Select Lab Surveillance", CombinedGraphWindow = V List Box());
CombinedGraphWindow << append(Report(MeanPlot)) << append(Report(BoxPlot));

ただし、列スイッチャーは新しいウィンドウに含まれていません。1つの列スイッチャーは両方のグラフを「カバー」できないことを知っているので、グラフが2つの別々のウィンドウにある場合と同じように、グラフごとに1つ必要です。どうすればできますか？

 

ジュリー 

Re：1つのウィンドウで2つのグラフを組み合わせる

データテーブルを忘れた

Re：1つのウィンドウで2つのグラフを組み合わせる

結合されたウィンドウで最終的に何が表示されるかを見ると、それはグラフビルダーの表示のコピーにすぎず、変更などの機能がないことがわかります。

あなたがする必要があるのは、グラフビルダーの実際のコードを表示ウィンドウに追加することです...

New Window( "Select Lab Surveillance", CombinedGraphWindow = V List Box() );
CombinedGraphWindow << append(
 MeanPlot = LBSelectSplit << Graph Builder(
  Size( 1181, 745 ),
  Show Control Panel( 0 ),
  Show Legend( 0 ),
  Fit to Window( "Maintain Aspect Ratio" ),
  Variables(
   X( :Visit Name, Order By( :Visit Number, Ascending, Order Statistic( "Mean" ) ) ),
   Y( :Alanine Aminotransferase )
  ),
  Elements( Line( X, Y, Legend( 6 ), Error Bars( "Standard Error" ) ) ),
  Column Switcher(
   :Alanine Aminotransferase,
   {:Alanine Aminotransferase, :Albumin, :Alkaline Phosphatase, :Amylase, :Aspartate Aminotransferase,
   :Bilirubin, :C Reactive Protein, :Calcitonin, :Calcium, :Cholesterol, :Creatine Kinase,
   :Creatinine, :Eosinophils, :Erythrocytes, :Gamma Glutamyl Transferase,
   :Name( "Glomerular Filtration Rate, Estimated" ), :HDL Cholesterol, :Hematocrit, :Hemoglobin,
   :Hemoglobin A1C, :LDL Cholesterol, :Leukocytes, :Lipase, :Lymphocytes, :Monocytes, :Neutrophils,
   :Platelets, :Potassium, :Sodium, :Triglycerides, :Urea, :VLDL Cholesterol}
  )
 )
) << append(
 BoxPlot = LBSelectSplit << Graph Builder(
  Size( 1199, 762 ),
  Show Control Panel( 0 ),
  Show Legend( 0 ),
  Variables(
   X( :Visit Name, Order By( :Visit Number, Ascending, Order Statistic( "Mean" ) ) ),
   Y( :Alanine Aminotransferase )
  ),
  Elements( Box Plot( X, Y, Legend( 6 ) ) ),
  Column Switcher(
   :Alanine Aminotransferase,
   {:Alanine Aminotransferase, :Albumin, :Alkaline Phosphatase, :Amylase, :Aspartate Aminotransferase,
   :Bilirubin, :C Reactive Protein, :Calcitonin, :Calcium, :Cholesterol, :Creatine Kinase,
   :Creatinine, :Eosinophils, :Erythrocytes, :Gamma Glutamyl Transferase,
   :Name( "Glomerular Filtration Rate, Estimated" ), :HDL Cholesterol, :Hematocrit, :Hemoglobin,
   :Hemoglobin A1C, :LDL Cholesterol, :Leukocytes, :Lipase, :Lymphocytes, :Monocytes, :Neutrophils,
   :Platelets, :Potassium, :Sodium, :Triglycerides, :Urea, :VLDL Cholesterol}
  )
 )
);

Re：1つのウィンドウで2つのグラフを組み合わせる

間違いではありませんが、ここで表示ボックスの追加機能を使用する必要はありません。New Window（）は、グラフビルダーの割り当ての結果を使用して、独自のウィンドウを作成できます。この方法は、私の意見では、よりシンプルでクリーンなコードになります。

 

New Window( "Select Lab Surveillance",
 MeanPlot = LBSelectSplit << Graph Builder(
  Size( 1181, 745 ),
  Show Control Panel( 0 ),
  Show Legend( 0 ),
  Fit to Window( "Maintain Aspect Ratio" ),
  Variables(
   X( :Visit Name, Order By( :Visit Number, Ascending, Order Statistic( "Mean" ) ) ),
   Y( :Alanine Aminotransferase )
  ),
  Elements( Line( X, Y, Legend( 6 ), Error Bars( "Standard Error" ) ) ),
  Column Switcher(
   :Alanine Aminotransferase,
   {:Alanine Aminotransferase, :Albumin, :Alkaline Phosphatase, :Amylase, :Aspartate Aminotransferase,
   :Bilirubin, :C Reactive Protein, :Calcitonin, :Calcium, :Cholesterol, :Creatine Kinase,
   :Creatinine, :Eosinophils, :Erythrocytes, :Gamma Glutamyl Transferase,
   :Name( "Glomerular Filtration Rate, Estimated" ), :HDL Cholesterol, :Hematocrit, :Hemoglobin,
   :Hemoglobin A1C, :LDL Cholesterol, :Leukocytes, :Lipase, :Lymphocytes, :Monocytes, :Neutrophils,
   :Platelets, :Potassium, :Sodium, :Triglycerides, :Urea, :VLDL Cholesterol}
  )
 ),
 BoxPlot = LBSelectSplit << Graph Builder(
  Size( 1199, 762 ),
  Show Control Panel( 0 ),
  Show Legend( 0 ),
  Variables(
   X( :Visit Name, Order By( :Visit Number, Ascending, Order Statistic( "Mean" ) ) ),
   Y( :Alanine Aminotransferase )
  ),
  Elements( Box Plot( X, Y, Legend( 6 ) ) ),
  Column Switcher(
   :Alanine Aminotransferase,
   {:Alanine Aminotransferase, :Albumin, :Alkaline Phosphatase, :Amylase, :Aspartate Aminotransferase,
   :Bilirubin, :C Reactive Protein, :Calcitonin, :Calcium, :Cholesterol, :Creatine Kinase,
   :Creatinine, :Eosinophils, :Erythrocytes, :Gamma Glutamyl Transferase,
   :Name( "Glomerular Filtration Rate, Estimated" ), :HDL Cholesterol, :Hematocrit, :Hemoglobin,
   :Hemoglobin A1C, :LDL Cholesterol, :Leukocytes, :Lipase, :Lymphocytes, :Monocytes, :Neutrophils,
   :Platelets, :Potassium, :Sodium, :Triglycerides, :Urea, :VLDL Cholesterol}
  )
 )
);