262097_zh-TW

liliconcom

需要有關二元圖表自動重新調用的幫助

使用大類樣本數據。 我正在嘗試製作一個簡單的腳本，通過 x 發布 y 。 它有一個 UCL 設置，並且腳本還設置了自動重新計算。 我想讓這個腳本使用自動重新計算，這樣當我隱藏和排除一些數據點時，它會調整 y 軸。 但是，如果我想隱藏和排除 UCL 以下的點（例如大於 100 的任何點），我仍然希望 y 軸調整但不低於 UCL。 有沒有辦法做到這一點？

 

Bivariate(
 Y( :weight ),
 X( :height ),
 Automatic Recalc( 1 ),
 SendToReport( Dispatch( {}, "2", ScaleBox, {Add Ref Line( 120, Solid, "Medium Dark Red", "UCL 120", 2 )} ) )
)

數據混合和清理回复：需要有關雙變量圖表自動重新調用的幫助正是我需要的。 謝謝。回复：需要有關雙變量圖表自動重新調用的幫助

我相信這是我的誤讀，但請嘗試下面的一個。我認為它接近你想要的，如果不是，你應該能夠調整它以滿足你需要的邏輯。

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );
biv = Bivariate(
 Y( :weight ),
 X( :height ),
 Automatic Recalc( 1 ),
 SendToReport(
  Dispatch( {}, "2", ScaleBox, {Add Ref Line( 120, Solid, "Medium Dark Red", "UCL 120", 2 )} )
 )
);

Report( biv )[FrameBox( 1 )] << add graphics script(
 If( Col Max( If( Excluded( Row State( Row() ) ) == 1, ., :weight ) ) < 120,
  Report( biv )[AxisBox( 1 )] << Max( 125 ),
  Report( biv )[AxisBox( 1 )] << Max( Col Max( If( Excluded( Row State( Row() ) ) == 1, ., :weight ) ) )
 )
);

回复：需要有關雙變量圖表自動重新調用的幫助

@tx尼爾森為您提供解決方案，只需將最小值更改為最大值即可。

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );
biv = Bivariate(
 Y( :weight ),
 X( :height ),
 Automatic Recalc( 1 ),
 SendToReport(
  Dispatch( {}, "2", ScaleBox, {Add Ref Line( 120, Solid, "Medium Dark Red", "UCL 120", 2 )} )
 )
);

Report( biv )[FrameBox( 1 )] << add graphics script(
 If( (Report( biv )[AxisBox( 1 )] << get max) < 120,
  Report( biv )[AxisBox( 1 )] << Max( 120 )
 )
);

另一種方法是使用行狀態處理程序函數。 見下文。 如果您是 JSL 新手，Jim 的解決方案是更安全的解決方案。

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );
::ymax = Col Max(:weight);

f = function({a}, ::ymax= Maximum( Col Max(:weight), 120) );
dt << Make RowState Handler(f);
 
biv = Bivariate(
 Y( :weight ),
 X( :height ),
 Automatic Recalc( 1 ),
 SendToReport(
  Dispatch( {}, "2", ScaleBox, 
  {Add Ref Line( 120, Solid, "Medium Dark Red", "UCL 120", 2 )},
    {Min( 60 ), Max( ::ymax ), Inc( 20 ), Minor Ticks( 0 )}
  )
 )
);

回复：需要有關雙變量圖表自動重新調用的幫助事實上，我可能描述得不好。 當 UCL 之上沒有點時使用自動計算時，我希望 y 軸上的最大值保持在 UCL。回复：需要有關雙變量圖表自動重新調用的幫助

像這樣的東西可能會起作用

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );
biv = Bivariate(
 Y( :weight ),
 X( :height ),
 Automatic Recalc( 1 ),
 SendToReport(
  Dispatch( {}, "2", ScaleBox, {Add Ref Line( 120, Solid, "Medium Dark Red", "UCL 120", 2 )} )
 )
);

Report( biv )[FrameBox( 1 )] << add graphics script(
 If( (Report( biv )[AxisBox( 1 )] << get min) < 120,
  Report( biv )[AxisBox( 1 )] << Min( 120 )
 )
);