262097_es-ES

liliconcom

Re: Necesito ayuda con la recuperación automática en el gráfico bivariado

Algo como esto podría funcionar

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );
biv = Bivariate(
 Y( :weight ),
 X( :height ),
 Automatic Recalc( 1 ),
 SendToReport(
  Dispatch( {}, "2", ScaleBox, {Add Ref Line( 120, Solid, "Medium Dark Red", "UCL 120", 2 )} )
 )
);

Report( biv )[FrameBox( 1 )] << add graphics script(
 If( (Report( biv )[AxisBox( 1 )] << get min) < 120,
  Report( biv )[AxisBox( 1 )] << Min( 120 )
 )
);

Re: Necesito ayuda con la recuperación automática en el gráfico bivariadoEn realidad, puedo haberlo descrito mal. Me gustaría que el máximo en el eje y permanezca en el UCL cuando se usa el cálculo automático cuando no hay puntos por encima del UCL.Necesito ayuda con la recuperación automática en el gráfico bivariado

Usando los datos de muestra de clase grande . Estoy tratando de hacer un script fácil que publique y sobre x. Tiene un conjunto UCL y la secuencia de comandos también tiene activada la recalc. Automática. Me gustaría que esta secuencia de comandos use el recalc automático para que cuando oculte y excluya algunos puntos de datos, ajustará el eje y. Pero, si quiero ocultar y excluir puntos debajo de la UCL (digamos algo mayor que 100), todavía quiero que el eje y se ajuste pero no baje más que la UCL. ¿Hay una manera de hacerlo?

 

Bivariate(
 Y( :weight ),
 X( :height ),
 Automatic Recalc( 1 ),
 SendToReport( Dispatch( {}, "2", ScaleBox, {Add Ref Line( 120, Solid, "Medium Dark Red", "UCL 120", 2 )} ) )
)

ScriptingRe: Necesito ayuda con la recuperación automática en el gráfico bivariado

@txnelson le proporcionó la solución, simplemente cambie el Min al Max.

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );
biv = Bivariate(
 Y( :weight ),
 X( :height ),
 Automatic Recalc( 1 ),
 SendToReport(
  Dispatch( {}, "2", ScaleBox, {Add Ref Line( 120, Solid, "Medium Dark Red", "UCL 120", 2 )} )
 )
);

Report( biv )[FrameBox( 1 )] << add graphics script(
 If( (Report( biv )[AxisBox( 1 )] << get max) < 120,
  Report( biv )[AxisBox( 1 )] << Max( 120 )
 )
);

Otro enfoque es utilizar una función de controlador de estado de fila. Vea abajo. Si es nuevo en JSL, la solución de Jim es una solución más segura.

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );
::ymax = Col Max(:weight);

f = function({a}, ::ymax= Maximum( Col Max(:weight), 120) );
dt << Make RowState Handler(f);
 
biv = Bivariate(
 Y( :weight ),
 X( :height ),
 Automatic Recalc( 1 ),
 SendToReport(
  Dispatch( {}, "2", ScaleBox, 
  {Add Ref Line( 120, Solid, "Medium Dark Red", "UCL 120", 2 )},
    {Min( 60 ), Max( ::ymax ), Inc( 20 ), Minor Ticks( 0 )}
  )
 )
);

Re: Necesito ayuda con la recuperación automática en el gráfico bivariado

Creo que fue mi mala lectura, pero prueba el siguiente.  Creo que está cerca de lo que quieres, y si no, deberías poder ajustarlo para cumplir con la lógica que necesitas.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );
biv = Bivariate(
 Y( :weight ),
 X( :height ),
 Automatic Recalc( 1 ),
 SendToReport(
  Dispatch( {}, "2", ScaleBox, {Add Ref Line( 120, Solid, "Medium Dark Red", "UCL 120", 2 )} )
 )
);

Report( biv )[FrameBox( 1 )] << add graphics script(
 If( Col Max( If( Excluded( Row State( Row() ) ) == 1, ., :weight ) ) < 120,
  Report( biv )[AxisBox( 1 )] << Max( 125 ),
  Report( biv )[AxisBox( 1 )] << Max( Col Max( If( Excluded( Row State( Row() ) ) == 1, ., :weight ) ) )
 )
);

Re: Necesito ayuda con la recuperación automática en el gráfico bivariadoExactamente lo que necesito. Gracias.