262097_zh-CN

liliconcom

回复：需要帮助以自动调整双变量图表

这样的事情可能会起作用

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );
biv = Bivariate(
 Y( :weight ),
 X( :height ),
 Automatic Recalc( 1 ),
 SendToReport(
  Dispatch( {}, "2", ScaleBox, {Add Ref Line( 120, Solid, "Medium Dark Red", "UCL 120", 2 )} )
 )
);

Report( biv )[FrameBox( 1 )] << add graphics script(
 If( (Report( biv )[AxisBox( 1 )] << get min) < 120,
  Report( biv )[AxisBox( 1 )] << Min( 120 )
 )
);

回复：需要帮助以自动调整双变量图表实际上，我可能对此描述不佳。当在UCL上方没有点时使用自动计算时，我希望y轴上的最大值保持在UCL处。在双变量图表上需要自动标定方面的帮助

使用大样本数据 。我正在尝试制作一个在x上发布y的简单脚本。它具有UCL设置，并且脚本还将自动重新计算设置为on。我希望该脚本使用自动重新计算，因此当我隐藏和排除一些数据点时，它将调整y轴。但是，如果我想隐藏和排除UCL以下的点（例如大于100的点），我仍然希望y轴进行调整，但不要低于UCL。有没有办法做到这一点？

 

Bivariate(
 Y( :weight ),
 X( :height ),
 Automatic Recalc( 1 ),
 SendToReport( Dispatch( {}, "2", ScaleBox, {Add Ref Line( 120, Solid, "Medium Dark Red", "UCL 120", 2 )} ) )
)

脚本编写回复：需要帮助以自动调整双变量图表

@txnelson 为您提供解决方案，只需将最小值更改为最大值。

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );
biv = Bivariate(
 Y( :weight ),
 X( :height ),
 Automatic Recalc( 1 ),
 SendToReport(
  Dispatch( {}, "2", ScaleBox, {Add Ref Line( 120, Solid, "Medium Dark Red", "UCL 120", 2 )} )
 )
);

Report( biv )[FrameBox( 1 )] << add graphics script(
 If( (Report( biv )[AxisBox( 1 )] << get max) < 120,
  Report( biv )[AxisBox( 1 )] << Max( 120 )
 )
);

另一种方法是使用行状态处理程序功能。见下文。如果您不熟悉JSL，那么Jim的解决方案将是一个更安全的解决方案。

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );
::ymax = Col Max(:weight);

f = function({a}, ::ymax= Maximum( Col Max(:weight), 120) );
dt << Make RowState Handler(f);
 
biv = Bivariate(
 Y( :weight ),
 X( :height ),
 Automatic Recalc( 1 ),
 SendToReport(
  Dispatch( {}, "2", ScaleBox, 
  {Add Ref Line( 120, Solid, "Medium Dark Red", "UCL 120", 2 )},
    {Min( 60 ), Max( ::ymax ), Inc( 20 ), Minor Ticks( 0 )}
  )
 )
);

回复：需要帮助以自动调整双变量图表

我认为这是我的误读，但请尝试以下一种。  我认为它接近您想要的内容，如果没有，您应该可以对其进行调整以满足您所需的逻辑。

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );
biv = Bivariate(
 Y( :weight ),
 X( :height ),
 Automatic Recalc( 1 ),
 SendToReport(
  Dispatch( {}, "2", ScaleBox, {Add Ref Line( 120, Solid, "Medium Dark Red", "UCL 120", 2 )} )
 )
);

Report( biv )[FrameBox( 1 )] << add graphics script(
 If( Col Max( If( Excluded( Row State( Row() ) ) == 1, ., :weight ) ) < 120,
  Report( biv )[AxisBox( 1 )] << Max( 125 ),
  Report( biv )[AxisBox( 1 )] << Max( Col Max( If( Excluded( Row State( Row() ) ) == 1, ., :weight ) ) )
 )
);

回复：需要帮助以自动调整双变量图表正是我所需要的。谢谢。