262097_ja-JP

liliconcom

Re：二変量グラフの自動再調整のヘルプが必要

このような何かがうまくいくかもしれません

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );
biv = Bivariate(
 Y( :weight ),
 X( :height ),
 Automatic Recalc( 1 ),
 SendToReport(
  Dispatch( {}, "2", ScaleBox, {Add Ref Line( 120, Solid, "Medium Dark Red", "UCL 120", 2 )} )
 )
);

Report( biv )[FrameBox( 1 )] << add graphics script(
 If( (Report( biv )[AxisBox( 1 )] << get min) < 120,
  Report( biv )[AxisBox( 1 )] << Min( 120 )
 )
);

Re：二変量グラフの自動再調整のヘルプが必要実際、私はそれを不十分に説明したかもしれません。UCLの上にポイントがないときに自動計算が使用されている場合、y軸の最大値をUCLのままにしておく必要があります。2変量グラフの自動再計算のヘルプが必要

ビッグクラスのサンプルデータの使用 。私はxよりもyを公開する簡単なスクリプトを作成しようとしています。UCLセットがあり、スクリプトにも自動再計算がオンに設定されています。このスクリプトで自動再計算を使用したいので、一部のデータポイントを非表示にして除外すると、y軸が調整されます。しかし、UCLの下にあるポイントを非表示にして除外したい場合（たとえば、100より大きいもの）、y軸を調整してUCLよりも低くしないでください。それを行う方法はありますか？

 

Bivariate(
 Y( :weight ),
 X( :height ),
 Automatic Recalc( 1 ),
 SendToReport( Dispatch( {}, "2", ScaleBox, {Add Ref Line( 120, Solid, "Medium Dark Red", "UCL 120", 2 )} ) )
)

スクリプティングRe：二変量グラフの自動再調整のヘルプが必要

@txnelson 解決策を提供したら、最小値を最大値に変更します。

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );
biv = Bivariate(
 Y( :weight ),
 X( :height ),
 Automatic Recalc( 1 ),
 SendToReport(
  Dispatch( {}, "2", ScaleBox, {Add Ref Line( 120, Solid, "Medium Dark Red", "UCL 120", 2 )} )
 )
);

Report( biv )[FrameBox( 1 )] << add graphics script(
 If( (Report( biv )[AxisBox( 1 )] << get max) < 120,
  Report( biv )[AxisBox( 1 )] << Max( 120 )
 )
);

別のアプローチは、行状態ハンドラー関数を使用することです。下記参照。JSLを初めて使用する場合は、ジムのソリューションがより安全なソリューションです。

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );
::ymax = Col Max(:weight);

f = function({a}, ::ymax= Maximum( Col Max(:weight), 120) );
dt << Make RowState Handler(f);
 
biv = Bivariate(
 Y( :weight ),
 X( :height ),
 Automatic Recalc( 1 ),
 SendToReport(
  Dispatch( {}, "2", ScaleBox, 
  {Add Ref Line( 120, Solid, "Medium Dark Red", "UCL 120", 2 )},
    {Min( 60 ), Max( ::ymax ), Inc( 20 ), Minor Ticks( 0 )}
  )
 )
);

Re：二変量グラフの自動再調整のヘルプが必要

誤解だと思いますが、以下をお試しください。  私はそれがあなたが望むものに近いと思います、そうでなければ、あなたはそれをあなたが必要とするロジックを満たすためにそれを微調整できるはずです。

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );
biv = Bivariate(
 Y( :weight ),
 X( :height ),
 Automatic Recalc( 1 ),
 SendToReport(
  Dispatch( {}, "2", ScaleBox, {Add Ref Line( 120, Solid, "Medium Dark Red", "UCL 120", 2 )} )
 )
);

Report( biv )[FrameBox( 1 )] << add graphics script(
 If( Col Max( If( Excluded( Row State( Row() ) ) == 1, ., :weight ) ) < 120,
  Report( biv )[AxisBox( 1 )] << Max( 125 ),
  Report( biv )[AxisBox( 1 )] << Max( Col Max( If( Excluded( Row State( Row() ) ) == 1, ., :weight ) ) )
 )
);

Re：二変量グラフの自動再調整のヘルプが必要まさに私が必要とするもの。ありがとうございました。