261447_es-ES

liliconcom

Tamaño de fotograma con varios gráficos en el cuadro de lista

Trazo 3 gráficos para cada VISUAL_ID. Uno para resistencia, uno para DRP y otro para temperatura. El problema que tengo es que cuando hay varios VISUAL_ID, los gráficos se vuelven muy pequeños. Configuré el tamaño del gráfico en el Generador de gráficos, pero parece estar distribuido en todos los gráficos. El ancho se mantiene constante entre todos los gráficos, pero la longitud de cada gráfico varía dependiendo de cuántos VISUAL_ID se trazan. Me gustaría que todos los gráficos tengan el mismo tamaño de 500x1000, sin importar cuántos VISUAL_ID se tracen.

 

¿Ayuda?

 

 

New Window( "Resistance - Application",
 H List Box(
  
  Graph Builder(
   Size(500, 1000),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Automatic Recalc( 0 ),
   Variables( X( :STRESS_TIME_HOUR_QTY ), Y( :RESISTANCE_OHM_QTY ), Page( :VISUAL_ID ) ),
   Elements( Points( X, Y, Legend( 6 ) ) )
  ), 
  
  Graph Builder(
   Size(500, 1000),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Automatic Recalc( 0 ),
   Variables( X( :STRESS_TIME_HOUR_QTY ), Y( :DRP ), Page( :VISUAL_ID ) ),
   Elements( Points( X, Y, Legend( 4 ) ) )
  ), 
  
  Graph Builder(
   Size(500, 1000),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Automatic Recalc( 0 ),
   Variables( X( :STRESS_TIME_HOUR_QTY ), Y( :TEMPERATURE_OVEN_CELSIUS_QTY ), Page( :VISUAL_ID ) ),
   Elements( Points( X, Y, Legend( 6 ) ) )
  )
  
  
  
 )
  


)<< save Journal(path1 || "Resistance.jrn");

Re: Tamaño del marco con múltiples gráficos en el cuadro de lista

Esto puede ser un largo camino, pero el siguiente script generará cada gráfico en un tamaño de 500x500 y apilará las páginas separadas una encima de la otra, con las diferentes instancias del generador de gráficos organizadas horizontalmente.  Utiliza una metodología totalmente diferente a la capacidad de la página en Graph Builder, pero ofrece el mismo resultado pero con un tamaño de gráfico de tamaño estándar por página.

El ejemplo usa la tabla de datos Big Class, y solo defino 2 gráficos en lugar de su ejemplo de 3 gráficos, pero la expansión sería simple.

Names Default To Here( 1 );
dt = Current Data Table();

Summarize( page = by( :sex ) );

New Window( "Resistance - Application", hlb = H List Box() );
 
bb = Border Box( top( 10 ), bottom( 10 ), Left( 10 ), Right( 10 ), sides( 15 ) ,
vlb = V List Box());
For( i = 1, i <= N Items( page ), i++,
 vlb << append(
  Eval(
   Parse(
    "gb = dt << Graph Builder(
   Size(500, 500),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Automatic Recalc( 0 ),
   Variables( X( :age ), Y( :weight ) ),
   Elements( Points( X, Y, Legend( 6 ) ) ),where(:sex == \!""
     || page[i] || "\!"));"
   )
  )
 )
);
hlb << append (bb );

bb = Border Box( top( 10 ), bottom( 10 ), Left( 10 ), Right( 10 ), sides( 15 ) ,
vlb = V List Box());
For( i = 1, i <= N Items( page ), i++,
 vlb << append(
  Eval(
   Parse(
    "gb = dt << Graph Builder(
   Size(500, 500),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Automatic Recalc( 0 ),
   Variables( X( :age ), Y( :Height ) ),
   Elements( Points( X, Y, Legend( 6 ) ) ),where(:sex == \!""
     || page[i] || "\!"));"
   )
  )
 )
);
hlb << append (bb );

 

Re: Tamaño del marco con múltiples gráficos en el cuadro de lista

Funcionó perfectamente! ¡Gracias!