261447_ja-JP

liliconcom

リストボックスに複数のグラフがあるフレームサイズ

VISUAL_IDごとに3つのグラフをプロットします。1つは抵抗用、1つはDRP用、もう1つは温度用です。私が抱えている問題は、VISUAL_IDが複数ある場合、グラフが非常に小さくなるということです。グラフビルダーでグラフサイズを設定しましたが、すべてのグラフに分布しているようです。幅はすべてのグラフで一定ですが、各グラフの長さは、プロットされるVISUAL_IDの数によって異なります。プロットされるVISUAL_IDの数に関係なく、すべてのグラフを500x1000の同じサイズにしたいと思います。

 

助けて？

 

 

New Window( "Resistance - Application",
 H List Box(
  
  Graph Builder(
   Size(500, 1000),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Automatic Recalc( 0 ),
   Variables( X( :STRESS_TIME_HOUR_QTY ), Y( :RESISTANCE_OHM_QTY ), Page( :VISUAL_ID ) ),
   Elements( Points( X, Y, Legend( 6 ) ) )
  ), 
  
  Graph Builder(
   Size(500, 1000),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Automatic Recalc( 0 ),
   Variables( X( :STRESS_TIME_HOUR_QTY ), Y( :DRP ), Page( :VISUAL_ID ) ),
   Elements( Points( X, Y, Legend( 4 ) ) )
  ), 
  
  Graph Builder(
   Size(500, 1000),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Automatic Recalc( 0 ),
   Variables( X( :STRESS_TIME_HOUR_QTY ), Y( :TEMPERATURE_OVEN_CELSIUS_QTY ), Page( :VISUAL_ID ) ),
   Elements( Points( X, Y, Legend( 6 ) ) )
  )
  
  
  
 )
  


)<< save Journal(path1 || "Resistance.jrn");

Re：リストボックスに複数のグラフがあるフレームサイズ

これは長い道のりかもしれませんが、以下のスクリプトは各グラフを500x500サイズで出力し、異なるグラフビルダーインスタンスが水平に配置された状態で、個別のページを積み重ねます。  グラフビルダーのページ機能を使用する方法とはまったく異なる方法を使用しますが、同じ出力を提供しますが、ページあたりの標準サイズのグラフサイズを使用します。

この例ではBig Classデータテーブルを使用しており、3つのグラフの例ではなく2つのグラフのみを定義していますが、拡張は簡単です。

Names Default To Here( 1 );
dt = Current Data Table();

Summarize( page = by( :sex ) );

New Window( "Resistance - Application", hlb = H List Box() );
 
bb = Border Box( top( 10 ), bottom( 10 ), Left( 10 ), Right( 10 ), sides( 15 ) ,
vlb = V List Box());
For( i = 1, i <= N Items( page ), i++,
 vlb << append(
  Eval(
   Parse(
    "gb = dt << Graph Builder(
   Size(500, 500),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Automatic Recalc( 0 ),
   Variables( X( :age ), Y( :weight ) ),
   Elements( Points( X, Y, Legend( 6 ) ) ),where(:sex == \!""
     || page[i] || "\!"));"
   )
  )
 )
);
hlb << append (bb );

bb = Border Box( top( 10 ), bottom( 10 ), Left( 10 ), Right( 10 ), sides( 15 ) ,
vlb = V List Box());
For( i = 1, i <= N Items( page ), i++,
 vlb << append(
  Eval(
   Parse(
    "gb = dt << Graph Builder(
   Size(500, 500),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Automatic Recalc( 0 ),
   Variables( X( :age ), Y( :Height ) ),
   Elements( Points( X, Y, Legend( 6 ) ) ),where(:sex == \!""
     || page[i] || "\!"));"
   )
  )
 )
);
hlb << append (bb );

 

Re：リストボックスに複数のグラフがあるフレームサイズ

完璧に働きました！ありがとう！