261447_it-IT

liliconcom

Dimensione della cornice con più grafici nella casella di riepilogo

Traccio 3 grafici per ogni VISUAL_ID. Uno per resistenza, uno per DRP e uno per temperatura. Il problema che sto riscontrando è che quando ci sono più VISUAL_ID, i grafici diventano molto piccoli. Ho impostato la dimensione del grafico in Graph Builder, ma questo sembra essere distribuito su tutti i grafici. La larghezza rimane costante tra tutti i grafici, ma la lunghezza di ciascun grafico varia a seconda di quanti VISUAL_ID sono tracciati. Vorrei che tutti i grafici avessero la stessa dimensione di 500x1000, indipendentemente da quanti VISUAL_ID sono tracciati.

 

Aiuto?

 

 

New Window( "Resistance - Application",
 H List Box(
  
  Graph Builder(
   Size(500, 1000),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Automatic Recalc( 0 ),
   Variables( X( :STRESS_TIME_HOUR_QTY ), Y( :RESISTANCE_OHM_QTY ), Page( :VISUAL_ID ) ),
   Elements( Points( X, Y, Legend( 6 ) ) )
  ), 
  
  Graph Builder(
   Size(500, 1000),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Automatic Recalc( 0 ),
   Variables( X( :STRESS_TIME_HOUR_QTY ), Y( :DRP ), Page( :VISUAL_ID ) ),
   Elements( Points( X, Y, Legend( 4 ) ) )
  ), 
  
  Graph Builder(
   Size(500, 1000),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Automatic Recalc( 0 ),
   Variables( X( :STRESS_TIME_HOUR_QTY ), Y( :TEMPERATURE_OVEN_CELSIUS_QTY ), Page( :VISUAL_ID ) ),
   Elements( Points( X, Y, Legend( 6 ) ) )
  )
  
  
  
 )
  


)<< save Journal(path1 || "Resistance.jrn");

Ri: Dimensione del fotogramma con più grafici nella casella Elenco

Questo potrebbe essere molto lontano, ma lo script seguente mostrerà ogni grafico con dimensioni 500x500 e impilerà le pagine separate una sopra l'altra, con le diverse istanze del generatore di grafici disposte orizzontalmente.  Utilizza una metodologia totalmente diversa rispetto all'utilizzo della funzionalità Pagina in Graph Builder, ma fornisce lo stesso output ma con dimensioni del grafico di dimensioni standard per pagina.

L'esempio usa la tabella dei dati di Big Class e io definisco solo 2 grafici invece del tuo esempio di 3 grafici, ma l'espansione sarebbe semplice.

Names Default To Here( 1 );
dt = Current Data Table();

Summarize( page = by( :sex ) );

New Window( "Resistance - Application", hlb = H List Box() );
 
bb = Border Box( top( 10 ), bottom( 10 ), Left( 10 ), Right( 10 ), sides( 15 ) ,
vlb = V List Box());
For( i = 1, i <= N Items( page ), i++,
 vlb << append(
  Eval(
   Parse(
    "gb = dt << Graph Builder(
   Size(500, 500),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Automatic Recalc( 0 ),
   Variables( X( :age ), Y( :weight ) ),
   Elements( Points( X, Y, Legend( 6 ) ) ),where(:sex == \!""
     || page[i] || "\!"));"
   )
  )
 )
);
hlb << append (bb );

bb = Border Box( top( 10 ), bottom( 10 ), Left( 10 ), Right( 10 ), sides( 15 ) ,
vlb = V List Box());
For( i = 1, i <= N Items( page ), i++,
 vlb << append(
  Eval(
   Parse(
    "gb = dt << Graph Builder(
   Size(500, 500),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Automatic Recalc( 0 ),
   Variables( X( :age ), Y( :Height ) ),
   Elements( Points( X, Y, Legend( 6 ) ) ),where(:sex == \!""
     || page[i] || "\!"));"
   )
  )
 )
);
hlb << append (bb );

 

Ri: Dimensione del fotogramma con più grafici nella casella Elenco

Ha funzionato perfettamente! Grazie!