Frame size with Multiple graphs in List box

rmiyasato

I plot 3 graphs for every VISUAL_ID. One for Resistance, one for DRP, and one for Temperature. The problem I'm having is that when there are multiple VISUAL_IDs, the graphs become very small. I set graph size in the Graph Builder, but that seems to be distributed over all the graphs. The width stays constant among all graphs, but the length of each graph varies depending on how many VISUAL_IDs are plotted. I would like all the graphs to be the same size of 500x1000, no matter how many VISUAL_IDs are plotted.

 

Help?

 

 

New Window( "Resistance - Application",
	H List Box(
		
		Graph Builder(
			Size(500, 1000),
			Show Control Panel( 0 ),
			Show Legend( 0 ),
			Automatic Recalc( 0 ),
			Variables( X( :STRESS_TIME_HOUR_QTY ), Y( :RESISTANCE_OHM_QTY ), Page( :VISUAL_ID ) ),
			Elements( Points( X, Y, Legend( 6 ) ) )
		), 
		
		Graph Builder(
			Size(500, 1000),
			Show Control Panel( 0 ),
			Show Legend( 0 ),
			Automatic Recalc( 0 ),
			Variables( X( :STRESS_TIME_HOUR_QTY ), Y( :DRP ), Page( :VISUAL_ID ) ),
			Elements( Points( X, Y, Legend( 4 ) ) )
		), 
		
		Graph Builder(
			Size(500, 1000),
			Show Control Panel( 0 ),
			Show Legend( 0 ),
			Automatic Recalc( 0 ),
			Variables( X( :STRESS_TIME_HOUR_QTY ), Y( :TEMPERATURE_OVEN_CELSIUS_QTY ), Page( :VISUAL_ID ) ),
			Elements( Points( X, Y, Legend( 6 ) ) )
		)
		
		
		
	)
		


)<< save Journal(path1 || "Resistance.jrn");

txnelson

This may be a long way around, but the below script will output each graph at a 500x500 size, and will stack the separate pages on top of each other, with the different graph builder instances being horizontally arranged.  It uses a totally different methodology than using the Page capability in Graph Builder, but it gives the same output but with a standard size graph size per page.

The example uses the Big Class data table, and I only define 2 graphs instead of your example of 3 graphs, but the expansion would be simple.

Names Default To Here( 1 );
dt = Current Data Table();

Summarize( page = by( :sex ) );

New Window( "Resistance - Application", hlb = H List Box() );
	
bb = Border Box( top( 10 ), bottom( 10 ), Left( 10 ), Right( 10 ), sides( 15 ) ,
vlb = V List Box());
For( i = 1, i <= N Items( page ), i++,
	vlb << append(
		Eval(
			Parse(
				"gb = dt << Graph Builder(
			Size(500, 500),
			Show Control Panel( 0 ),
			Show Legend( 0 ),
			Automatic Recalc( 0 ),
			Variables( X( :age ), Y( :weight ) ),
			Elements( Points( X, Y, Legend( 6 ) ) ),where(:sex == \!""
				 || page[i] || "\!"));"
			)
		)
	)
);
hlb << append (bb );

bb = Border Box( top( 10 ), bottom( 10 ), Left( 10 ), Right( 10 ), sides( 15 ) ,
vlb = V List Box());
For( i = 1, i <= N Items( page ), i++,
	vlb << append(
		Eval(
			Parse(
				"gb = dt << Graph Builder(
			Size(500, 500),
			Show Control Panel( 0 ),
			Show Legend( 0 ),
			Automatic Recalc( 0 ),
			Variables( X( :age ), Y( :Height ) ),
			Elements( Points( X, Y, Legend( 6 ) ) ),where(:sex == \!""
				 || page[i] || "\!"));"
			)
		)
	)
);
hlb << append (bb );