259139_es-ES

liliconcom

Ayuda con funciones personalizadas

hash = Function( {StringList},
 {StringListItem,HashString},
 For( StringListItem = 1, StringListItem <= Length( StringList ), StringListItem++,
  StringList[StringListItem] = Char( Eval( Stringlist[StringListItem] ) )
 );
 HashString = Hex( Blob MD5( Char To Blob( Concat Items( StringList ) ) ) );
);

Esta es una función hash que uso para crear identificaciones únicas.  La función actualmente toma una lista como argumento.  Me gustaría que tomara uno o más argumentos separados por comas.  Espero agregarlo a funciones personalizadas y ponerlo a disposición de otros usuarios.  Pensé que sería más fácil para los usuarios si aceptara múltiples argumentos separados por comas como la función Sum ().

 

¿Alguna idea?

 

Muchas gracias,

 

Juan

 

Re: Ayuda con función personalizada

Aquí hay un método que usa su código que permitiría la entrada de algunos valores máximos preestablecidos grandes, pero una lista variable de parámetros de entrada para su función hash

hash = Function( {a, b = "", c = "", d = ""}, // e="",f=""...…...z="")
 //{StringListItem,HashString},
 StringList = {};
 string# = 1;
 varList = {"a", "b", "c", "d"}; // .........."z"
 
 While( Eval( Parse( varlist[string#] ) ) != "",
  Insert Into( stringList, Eval( Parse( varlist[string#] ) ) );
  string# = string# + 1;
 );
 For( StringListItem = 1, StringListItem <= Length( StringList ), StringListItem++,
  StringList[StringListItem] = Char( Eval( Stringlist[StringListItem] ) )
 );
 HashString = Hex( Blob MD5( Char To Blob( Concat Items( StringList ) ) ) );
);

Re: Ayuda con función personalizada

Puede que no sea exactamente lo que estás buscando, pero podrías evadirlo si realmente es solo una lista de cadenas.  

 

Infinitos argumentos desconocidos son más fáciles con una lista.  

 

Names default to here(1);
hash = Function( {StringList},
 {StringListItem,HashString},
 For( StringListItem = 1, StringListItem <= Length( StringList ), StringListItem++,
  StringList[StringListItem] = Char( Eval( Stringlist[StringListItem] ) )
 );
 HashString = Hex( Blob MD5( Char To Blob( Concat Items( StringList ) ) ) );
);

different_hash = function({StringList}, 
 StringList = Evallist(StringList);
 Hex( Blob MD5( Char To Blob( Concat Items( StringList ) ) ) );
);

x = "2";
y = "a";
z = "Expr(b)";
b = "another string";

l = {x, y, z};
show(hash(l) == different_hash(l));

Re: Ayuda con función personalizada

@johnmoore ,

 

Esta es otra variación de @vince_faller y @txnelson Las soluciones de.

Names default to here(1);
hash = Function( {val1, val2=., val3=., val4=., val5=., val6=., val7=., val8=., val9=., val10=.},
 {i, StringListItem,HashString},
 if(IsList(val1), StringList = EvalList(val1),
  StringList={};
  For(i=1, i<=10,i++,
   Eval( Parse(EvalInsert("If( !IsMissing(val^i^) & IsString(val^i^), InsertInto(StringList, val^i^))" ) ) )
  );
 );
 //Show(StringList);
 For( StringListItem = 1, StringListItem <= Length( StringList ), StringListItem++,
  StringList[StringListItem] = Char( Eval( Stringlist[StringListItem] ) )
 );
 HashString = Hex( Blob MD5( Char To Blob( Concat Items( StringList ) ) ) );
);


x = "2";
y = "a";
z = "Expr(b)";
b = "another string";

hash(x,y,z);
l = {x, y, z};
show(hash(l), hash(x,y,z), hash( list(x,y,z) )  );&nbsp;&nbsp;//produces&nbsp;the same result&nbsp;

Tomaría algo de documentación / capacitación para sus usuarios, que se pueden ingresar hasta 10 argumentos de cadena o usar una lista si hay más de 10.

Re: Ayuda con función personalizadaMuchas gracias por tu solución!