257413_it-IT

liliconcom

Hai bisogno di aiuto - il comportamento di "Imposta script" è cambiato per il commutatore di colonne in JMP 15

Se si imposta uno script per il commutatore di colonne, in JMP 14 lo script viene eseguito dopo il completamento della commutazione della colonna, ma in JMP 15 viene eseguito prima della commutazione della colonna.  

 

L'esempio seguente crea un diagramma del generatore di grafici con un commutatore di colonne e imposta lo script del commutatore di colonne per stampare la versione JMP e il titolo dell'asse Y.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
nw = new window("Test",
 gb = Graph Builder(
  Size( 528, 464 ),
  Show Control Panel( 0 ),
  Variables( X( :name ), Y( :height ) ),
  Elements( Points( X, Y, Legend( 3 ) ) ),
  Column Switcher( :height, {:height, :weight} )
 )
);
nw[Listboxbox( 1 )] << set script(
 print(JMP Version());
 print(report(gb)[TextEditBox(4)]<< Get Text());
);

 

Se si esegue lo script in JMP 14 e si fa clic su "peso", si ottiene il seguente output.  Lo script viene eseguito dopo il passaggio della colonna.  

"14.1.0"
"weight"

Tuttavia, se si esegue lo stesso script in JMP 15, l'output è diverso.  Lo script viene eseguito prima del passaggio alla colonna.  

"15.1.0"
"height"

Questo cambiamento di comportamento interrompe uno dei miei script JMP che imposta l'asse min / max dopo il cambio di colonna.  Un modo per forzare l'esecuzione dello script dopo il cambio di colonna in JMP 15? Grazie.

 

 

Ri: Hai bisogno di aiuto - il comportamento di "Imposta script" è cambiato per il commutatore di colonne in JMP 15

Metterei il tuo problema nel supporto JMP, per ottenere il motivo ufficiale della modifica di JMP, tuttavia, se alleghi lo script al riquadro, otterrai i risultati desiderati

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
nw = new window("Test",
 gb = Graph Builder(
  Size( 528, 464 ),
  Show Control Panel( 0 ),
  Variables( X( :name ), Y( :height ) ),
  Elements( Points( X, Y, Legend( 3 ) ) ),
  Column Switcher( :height, {:height, :weight} )
 )
);
nw[framebox( 1 )] << add graphics script(
 print(JMP Version());
 print(report(gb)[TextEditBox(4)]<< Get Text());
);

Ri: Hai bisogno di aiuto - il comportamento di "Imposta script" è cambiato per il commutatore di colonne in JMP 15Grazie! Questa soluzione funziona in JMP 14 e 15.Ri: Hai bisogno di aiuto - il comportamento di "Imposta script" è cambiato per il commutatore di colonne in JMP 15

Puoi anche provare questo:

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
nw = New Window( "Test",
       gb = Graph Builder(
              Size( 528, 464 ),
              Show Control Panel( 0 ),
              Variables( X( :name ), Y( :height ) ),
              Elements( Points( X, Y, Legend( 3 ) ) ),
              Column Switcher( :height, {:height, :weight} )
       )
);
nw[Listboxbox( 1 )] << set script(
       Print( JMP Version() );
       Print( nw[Listboxbox( 1 )] << Get Selected() );
);

Ri: Hai bisogno di aiuto - il comportamento di "Imposta script" è cambiato per il commutatore di colonne in JMP 15

@paul_vezzetti Grazie per la tua risposta, ma purtroppo essere in grado di leggere il nome della nuova colonna non significa che la trama sia stata aggiornata con la nuova colonna.  In JMP 15, il cambio di colonna si verifica ancora dopo l'esecuzione dello script, sebbene il nuovo nome di colonna possa essere letto dal selettore di colonne.  Quindi, nel mio caso d'uso, voglio impostare la scala dell'asse per la nuova colonna su cui si passa, e questo non funzionerà perché JMP passa alla nuova colonna dopo aver impostato la scala, che azzera totalmente l'asse.  

Ri: Hai bisogno di aiuto - il comportamento di "Imposta script" è cambiato per il commutatore di colonne in JMP 15

Ho inviato questo problema al supporto di JMP e ho ottenuto la risposta:

Il team di sviluppo è stato in grado di determinare che il cambiamento nel comportamento dell'evento era intenzionale.  

 

Per ora, puoi usare la soluzione alternativa suggerita da Jim Nelson nella community.  Tuttavia, è previsto un nuovo approccio per la prossima versione di manutenzione di JMP 15 che consentirà di impostare uno script sul riferimento del commutatore di colonne.  Ciò garantirà che lo script venga eseguito al momento opportuno.  Ci aspettiamo che questa funzione sia disponibile nel periodo di luglio.