256138_es-ES

liliconcom

Cómo eliminar el cuadro de contorno que no se requiere de los gráficos

Hola

 

Quiero eliminar los recuadros que no son necesarios (o no quiero tener).

Siguiendo esta publicación https://community.jmp.com/t5/Discussions/How-to-show-fit-line-graphs-in-a-single-report-without-the/td-p/46302

Podemos borrar todas las casillas. Pero quiero mantener solo 'Sitio de ajuste lineal == 1' y la ecuación

 

 

 

así que lo intenté

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
biv = Bivariate(
 Y( :NPN1 ),
 X( :PNP1 ),
 Fit Where( :SITE == 1, Fit Line( {Line Color( {213, 72, 87} )} ) ));
 
biv[Outline Box(3)] << Delete; 
biv[Outline Box(4)] << Delete;
biv[Outline Box(5)] << Delete;

Pero aún esas cajas están ahí. El resultado esperado que necesito

 

 

 

 

Re: Como eliminar el cuadro de contorno que no se requiere de los gráficos

También considere usar <<

Report(biv)[Outline Box(3)] << Visibility("collapse");

"Contraer" ocultará el cuadro y eliminará el espacio que utiliza en el informe, sin eliminar el cuadro. Dos ventajas: (1) la numeración del cuadro de visualización no cambia y (2) algunas plataformas pueden confundirse al eliminar ciertos cuadros de visualización de los que dependen.

Me gusta el ejemplo final de Jim combinado con visibilidad:

dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
biv = Bivariate(
 Y( :NPN1 ),
 X( :PNP1 ),
 Fit Where( :SITE == 1, Fit Line( {Line Color( {213, 72, 87} )} ) ));
 
Report(biv)["Summary of Fit"] << Visibility("collapse");
Report(biv)["Analysis of Variance"] << Visibility("collapse");
Report(biv)["Parameter Estimates"] << Visibility("collapse");

lo que se explica por sí mismo a cualquiera que necesite entenderlo o mantenerlo más tarde.

 

Re: Como eliminar el cuadro de contorno que no se requiere de los gráficos

Vea mi JSL anotado a continuación

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
biv = Bivariate(
 Y( :NPN1 ),
 X( :PNP1 ),
 Fit Where( :SITE == 1, Fit Line( {Line Color( {213, 72, 87} )} ) ));
 
// When you are modifying the output from a Platform
// one needs to access the report
// Additionally, you need to delete the outline boxes either in
// reverse order as below, since the Butline Box nomenclature
// will change after the deletion of a box.  That is, if you delete
// Outline Box(3) first, once it is deleted, what was Outline Box(4)
// will now be the 3rd Outline Box etc. 
Report(biv)[Outline Box(5)] << Delete;
Report(biv)[Outline Box(4)] << Delete;
Report(biv)[Outline Box(3)] << Delete;

/*
// To illustrate this, you can actually eliminate the 3 Outline Boxes
// with the code below
Report(biv)[Outline Box(3)] << Delete;
Report(biv)[Outline Box(3)] << Delete;
Report(biv)[Outline Box(3)] << Delete;

// and an alternative method would be to use direct references
Report(biv)["Summary of Fit"] << Delete;
Report(biv)["Analysis of Variance"] << Delete;
Report(biv)["Parameter Estimates"] << Delete;
*/