256138_it-IT

liliconcom

Come eliminare outlinebox che non richiesto dai grafici

CIAO

 

Voglio eliminare outlinebox che non sono richiesti (o non voglio avere).

A seguito di questo post https://community.jmp.com/t5/Discussions/How-to-show-fit-line-graphs-in-a-single-report-without-the/td-p/46302

Possiamo eliminare tutte le caselle. Ma voglio mantenere solo 'Linear Fit Site == 1' e l'equazione

 

 

 

Così ho provato

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
biv = Bivariate(
 Y( :NPN1 ),
 X( :PNP1 ),
 Fit Where( :SITE == 1, Fit Line( {Line Color( {213, 72, 87} )} ) ));
 
biv[Outline Box(3)] << Delete; 
biv[Outline Box(4)] << Delete;
biv[Outline Box(5)] << Delete;

Ma quelle scatole sono ancora lì. L'output previsto di cui ho bisogno

 

 

 

 

Ri: Come eliminare la casella di riepilogo che non è richiesta dai grafici

Prendi in considerazione anche l'utilizzo di <<

Report(biv)[Outline Box(3)] << Visibility("collapse");

"Comprimi" nasconderà la casella e rimuoverà lo spazio che utilizza nel rapporto, senza eliminare la casella. Due vantaggi: (1) la numerazione della casella di visualizzazione non cambia e (2) alcune piattaforme potrebbero essere confuse eliminando determinate caselle di visualizzazione da cui dipendono.

Mi piace l'ultimo esempio di Jim combinato con Visibility:

dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
biv = Bivariate(
 Y( :NPN1 ),
 X( :PNP1 ),
 Fit Where( :SITE == 1, Fit Line( {Line Color( {213, 72, 87} )} ) ));
 
Report(biv)["Summary of Fit"] << Visibility("collapse");
Report(biv)["Analysis of Variance"] << Visibility("collapse");
Report(biv)["Parameter Estimates"] << Visibility("collapse");

che si spiega da sé a chiunque abbia bisogno di capirlo o mantenerlo in seguito.

 

Ri: Come eliminare la casella di riepilogo che non è richiesta dai grafici

Vedi il mio JSL annotato di seguito

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
biv = Bivariate(
 Y( :NPN1 ),
 X( :PNP1 ),
 Fit Where( :SITE == 1, Fit Line( {Line Color( {213, 72, 87} )} ) ));
 
// When you are modifying the output from a Platform
// one needs to access the report
// Additionally, you need to delete the outline boxes either in
// reverse order as below, since the Butline Box nomenclature
// will change after the deletion of a box.  That is, if you delete
// Outline Box(3) first, once it is deleted, what was Outline Box(4)
// will now be the 3rd Outline Box etc. 
Report(biv)[Outline Box(5)] << Delete;
Report(biv)[Outline Box(4)] << Delete;
Report(biv)[Outline Box(3)] << Delete;

/*
// To illustrate this, you can actually eliminate the 3 Outline Boxes
// with the code below
Report(biv)[Outline Box(3)] << Delete;
Report(biv)[Outline Box(3)] << Delete;
Report(biv)[Outline Box(3)] << Delete;

// and an alternative method would be to use direct references
Report(biv)["Summary of Fit"] << Delete;
Report(biv)["Analysis of Variance"] << Delete;
Report(biv)["Parameter Estimates"] << Delete;
*/