256138_de-DE

liliconcom

So löschen Sie nicht benötigte Outlineboxen aus Diagrammen

Hallo

 

Ich möchte Outlineboxen löschen, die nicht benötigt werden (oder die ich nicht haben möchte).

Nach diesem Beitrag https://community.jmp.com/t5/Discussions/How-to-show-fit-line-graphs-in-a-single-report-without-the/td-p/46302

Wir können alle Boxen löschen. Aber ich möchte nur 'Linear Fit Site == 1' und die Gleichung behalten

 

 

 

Also versuchte ich es

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
biv = Bivariate(
 Y( :NPN1 ),
 X( :PNP1 ),
 Fit Where( :SITE == 1, Fit Line( {Line Color( {213, 72, 87} )} ) ));
 
biv[Outline Box(3)] << Delete; 
biv[Outline Box(4)] << Delete;
biv[Outline Box(5)] << Delete;

Aber diese Kisten sind immer noch da. Die erwartete Ausgabe, die ich brauche

 

 

 

 

Betreff: So löschen Sie nicht benötigte Outlineboxen aus Diagrammen

Ziehen Sie auch die Verwendung von <<

Report(biv)[Outline Box(3)] << Visibility("collapse");

"Reduzieren" blendet das Feld aus und entfernt den Platz, den es im Bericht verwendet, ohne das Feld zu löschen. Zwei Vorteile: (1) die Displaybox-Nummerierung verschiebt sich nicht und (2) einige Plattformen könnten durch das Löschen bestimmter Displayboxen, von denen sie abhängen, verwirrt werden.

Ich mag Jims letztes Beispiel in Kombination mit Visibility:

dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
biv = Bivariate(
 Y( :NPN1 ),
 X( :PNP1 ),
 Fit Where( :SITE == 1, Fit Line( {Line Color( {213, 72, 87} )} ) ));
 
Report(biv)["Summary of Fit"] << Visibility("collapse");
Report(biv)["Analysis of Variance"] << Visibility("collapse");
Report(biv)["Parameter Estimates"] << Visibility("collapse");

was sich für jeden erklärt, der es später verstehen oder pflegen muss.

 

Betreff: So löschen Sie nicht benötigte Outlineboxen aus Diagrammen

Siehe meine kommentierte JSL unten

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
biv = Bivariate(
 Y( :NPN1 ),
 X( :PNP1 ),
 Fit Where( :SITE == 1, Fit Line( {Line Color( {213, 72, 87} )} ) ));
 
// When you are modifying the output from a Platform
// one needs to access the report
// Additionally, you need to delete the outline boxes either in
// reverse order as below, since the Butline Box nomenclature
// will change after the deletion of a box.  That is, if you delete
// Outline Box(3) first, once it is deleted, what was Outline Box(4)
// will now be the 3rd Outline Box etc. 
Report(biv)[Outline Box(5)] << Delete;
Report(biv)[Outline Box(4)] << Delete;
Report(biv)[Outline Box(3)] << Delete;

/*
// To illustrate this, you can actually eliminate the 3 Outline Boxes
// with the code below
Report(biv)[Outline Box(3)] << Delete;
Report(biv)[Outline Box(3)] << Delete;
Report(biv)[Outline Box(3)] << Delete;

// and an alternative method would be to use direct references
Report(biv)["Summary of Fit"] << Delete;
Report(biv)["Analysis of Variance"] << Delete;
Report(biv)["Parameter Estimates"] << Delete;
*/