256138_fr-FR

liliconcom

Comment supprimer une boîte de contour non requise des graphiques

Salut

 

Je veux supprimer les boîtes de contour qui ne sont pas nécessaires (ou que je ne veux pas avoir).

Suite à ce post https://community.jmp.com/t5/Discussions/How-to-show-fit-line-graphs-in-a-single-report-without-the/td-p/46302

Nous pouvons supprimer toutes les cases. Mais je veux garder uniquement 'Linear Fit Site == 1' et l'équation

 

 

 

Alors j'ai essayé

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
biv = Bivariate(
 Y( :NPN1 ),
 X( :PNP1 ),
 Fit Where( :SITE == 1, Fit Line( {Line Color( {213, 72, 87} )} ) ));
 
biv[Outline Box(3)] << Delete; 
biv[Outline Box(4)] << Delete;
biv[Outline Box(5)] << Delete;

Mais ces boîtes sont toujours là. La sortie attendue dont j'ai besoin

 

 

 

 

Re : Comment supprimer une boîte de contour qui n'est pas requise dans les graphiques

Pensez également à utiliser <<

Report(biv)[Outline Box(3)] << Visibility("collapse");

« Réduire » masquera la boîte et supprimera l'espace qu'elle utilise dans le rapport, sans supprimer la boîte. Deux avantages : (1) la numérotation des displaybox ne se déplace pas et (2) certaines plateformes peuvent être confondues en supprimant certains display box dont elles dépendent.

J'aime le dernier exemple de Jim combiné avec Visibility :

dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
biv = Bivariate(
 Y( :NPN1 ),
 X( :PNP1 ),
 Fit Where( :SITE == 1, Fit Line( {Line Color( {213, 72, 87} )} ) ));
 
Report(biv)["Summary of Fit"] << Visibility("collapse");
Report(biv)["Analysis of Variance"] << Visibility("collapse");
Report(biv)["Parameter Estimates"] << Visibility("collapse");

qui s'explique à quiconque a besoin de le comprendre ou de le maintenir plus tard.

 

Re : Comment supprimer une boîte de contour qui n'est pas requise dans les graphiques

Voir mon JSL annoté ci-dessous

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
biv = Bivariate(
 Y( :NPN1 ),
 X( :PNP1 ),
 Fit Where( :SITE == 1, Fit Line( {Line Color( {213, 72, 87} )} ) ));
 
// When you are modifying the output from a Platform
// one needs to access the report
// Additionally, you need to delete the outline boxes either in
// reverse order as below, since the Butline Box nomenclature
// will change after the deletion of a box.  That is, if you delete
// Outline Box(3) first, once it is deleted, what was Outline Box(4)
// will now be the 3rd Outline Box etc. 
Report(biv)[Outline Box(5)] << Delete;
Report(biv)[Outline Box(4)] << Delete;
Report(biv)[Outline Box(3)] << Delete;

/*
// To illustrate this, you can actually eliminate the 3 Outline Boxes
// with the code below
Report(biv)[Outline Box(3)] << Delete;
Report(biv)[Outline Box(3)] << Delete;
Report(biv)[Outline Box(3)] << Delete;

// and an alternative method would be to use direct references
Report(biv)["Summary of Fit"] << Delete;
Report(biv)["Analysis of Variance"] << Delete;
Report(biv)["Parameter Estimates"] << Delete;
*/