nav[aria-label="Primary Navigation"] { padding: 0; & ul { list-style: none; width: 100%; display: flex; flex-direction: row; justify-content: start; align-items: start; gap: 30px; padding: 0; & li { margin: 0; } & ul li { list-style: none; } } }

How can I import the column property into JMP data file?

Jackie_

Hi,

New challenge:

I've created the Column Property: Test Number in the 1st_file. Each test has unique Test Number which can be found in the column property as you can see below in highlighted red circle:

I've a 2nd JMP file which has 1 column(Test):

I'm trying to write a script which can copy the Test Number from the 1st file and assign the lowest value among of the Test in the 2nd file so my output will relatively look like this:

The Test Number are defined in the Column property of 1st file

E.g. Burning, Cooling, ESD = Min[Test Number] = 21

Output:

Any suggestions?

Thanks

1st_file.jmp

2nd file.jmp

Accepted answers

txnelson

@Jackie_ You have been shown all of these statements and functions in previous examples. You need to start to be able to try to put them together yourself. In computing, the only way you learn, is by making mistakes, and figuring out what the problem is. So below is a flow for a single entry from your 2nd_file, that returns the minimum test number. You should be able to put remainder of the code together.

names default to here(1);

dt1 = data table("1st_file ");
dt2 = data table("2nd file ");

dt2 << New Column("Test Number");

theWord = word(1,dt2:test[1],",");

theTest = column( dt1, theWord ) << get property("Test Number");

theWord = word(2,dt2:test[1],",");

theCompare = column( dt1, theWord ) << get property("Test Number");

If( theCompare < theWord, theTest = theCompare );

theWord = word(3,dt2:test[1],",");

theCompare = column( dt1, theWord ) << get property("Test Number");

If( theCompare < theWord, theTest = theCompare );

dt2:test number[1] = theTest;

Make sure you understand each line of the code, and if you do not, then ask questions specifically about what you do not understand.

txnelson

Names Default To Here( 1 );

dt1 = Data Table( "1st_file" );
dt2 = Data Table( "2nd file" );

For( i = 1, i <= N Rows( dt2 ), i++, 

	k = 1;
	While( Word( k, dt2:test[i], "," ) != "", 
	
		theWord = Word( k, dt2:test[i], "," );
		
		If( k == 1,
			theTest = Column( dt1, theWord ) << get property( "Test Number" ),
			theCompare = Column( dt1, theWord ) << get property( "Test Number" );

			If( theCompare < theTest,
				theTest = theCompare
			);
		);
		k++;
	);

	dt2:test number[i] = theTest;
);

txnelson

Good try on the If.....but the branching needs to be larger in scope. See below......

Names Default To Here( 1 );

dt1 = Data Table( "1st_file" );
dt2 = Data Table( "2nd file" );

dt2 << New Column( "Test Number" );

For( i = 1, i <= N Rows( dt2 ), i++,
	k = 1;
	While( Word( k, dt2:test[i], "," ) != "", 
	
		theWord = Word( k, dt2:test[i], "," );
		If( theWord != "N/A",
			If( k == 1,
				theTest = Column( dt1, theWord ) << get property( "Test Number" ),
				theCompare = Column( dt1, theWord ) << get property( "Test Number" );

				If( theCompare < theTest,
					theTest = theCompare
				);
			)
		,
			theTest = 0
		);
		k++;
	);  

	dt2:test number[i] = theTest;
);

All comments

txnelson

How does one know, which of the columns in 1st_file are evaluated in the calculation of a particular row's value in 2nd_file?

Jackie_

Hi @txnelson,

Right click on column properties and you will find Test Number and the Test Name

txnelson

In 1st_file, the columns only have 1 Column Property each, Test Number.....no Test Name.
Assuming that a second Column Property for each column of Test Name should have been in the 1st_File data table, then I believe the best way to access them would be to create an Associative Array. Then loop through each of the columns, extracting the 2 column properties, and placing them into the Associative Array. Finally, one would loop through the 2nd_file, row by row, and taking the value of the column Test, it would be a simple lookup against the Associative Array, to get the required test number.

Jackie_

Can you give a quick start example?