プレゼンテーション、トレーニング、出版で使用するために、塗りつぶされた正規分布曲線を作成する必要が何度かありました。 正規分布と同じくらい一般的で重要ですが、これを標準的な形状として、またはインターネット検索を使用して簡単に見つけることができると思いますが、私は必要なものを見つけるのにあまり運がありませんでした。
JMPには、グラフィックススクリプトを使用して、プロット上に線や幾何学的形状を描画するための優れた方法がいくつかあります。 このような形が欲しいなら
これを行う1つの方法は、正規分布関数を使用して、多角形を定義する座標点でベクトルを作成し、グラフィックススクリプトでそれをPolygon（）関数の引数として使用することです。
以下に示す関数は、まさにそれを行い、グラフィックススクリプトで使用できる評価された式を返します
func_VNormalShape = Function( // create a polygon that looks like a vertically oriented normal distribution
{_xloc, _yloc, _xscale = 1, _yscale = 1, _range=3, _scaleres=10},
{_VNormShapeX, _VNormShapeY},
// _xloc, _yloc is the "origin" for the normal curve (centered on Yloc, base of curve at xloc)
// _xscale is the scale magnification in the x-axis direction
// _yscale is the scale magnification in the y-axis direction
// range is the +/- range (in standard deviation) to draws the curve over
// scalres is the number of points per _yscale to use for determining the polygon. 10 generally works well, but if range is set to be large
// then scale_res should probably be increased.
// create a vector of y values to use for plotting the shape
_VNormShapeY = ((_yloc - _range * _yscale) :: (_yloc + _range * _yscale) :: (_yscale / _scaleres))`;
// create the filled polygon boundary points
_VNormShapeX = V Concat(
J( _range*2*_scaleres + 1, 1, _xloc ),
_xloc + Sqrt( 2 * Pi() ) * _yscale * _xscale * Normal Density( Sort Descending( _VNormShapeY ), _yloc, _yscale )
);
_VNormShapeY = V Concat(
_VNormShapeY,
Sort Descending( _VNormShapeY )
);
// substitute into the Polygon(function) the two vectorw with the boundary point X and Y values
// and evaluate the function
Eval( Substitute( Expr( Polygon( Expr( shape_x ), Expr( shape_y ) ) ), Expr( shape_x ), _VNormShapeX, Expr( shape_y ), _VNormShapeY ) );
); 次に、その関数を以下に示すようにGraph Box（）関数内で使用できます（これにより、上記の塗りつぶされた正規曲線が作成されます）。
_nw = New Window( "Vertical Normal Distribution",
_ob = Outline Box("Gray Vertical Filled Normal Distribution",
_hlb = H List Box(
_gb = Graph Box(
X Scale( 0, 1.1 ),
Y Scale( 1, 8 ),
Xname( "" ),
Yname( "" ),
Fill Color( "gray" );
func_VNormalShape( 0, 4.5, 1, 1, 3.4, 8 );
)
)
)
);
同じアプローチを他の確率分布に適用できます。
