253788_zh-TW

liliconcom

JSL 速度優化：避免重複調用“保存演示文稿”（“文件”、追加）

JMP 社區您好，

 

我在嘗試生成由多個期刊 (JRN) 文件中存儲的繪圖組裝而成的 PowerPoint 幻燈片方面取得了一些進展。

以下腳本產生正確的輸出，但速度相當慢，很可能是由於重複調用 << Save Presenting ("file_name",附加）。

我認為將不同的繪圖聚合在主容器（新窗口或新日誌）中，然後對整個主容器僅使用一次“保存演示文稿”會更快。 我該怎麼做：我對不同顯示結構的嵌套有點困惑。

Names Default to Here (1);

dummy = H List Box ();

dummy << Save Presentation ("C:\Users\sornstr\Desktop\TEMP PNG\NEW OUTPUT.pptx", Template ("C:\Users\sornstr\Desktop\JMP Scripts\SANDBOX\JMPExportTemplate_TS.pptx"), Outline Titles (Top Left));

jrn1 = Get Window("Journal: FIRST JOURNAL");
jrn2 = Get Window("Journal: SECOND JOURNAL");



For (i = 0, i <50, i++, 
 
 Plot1 = jrn1 [PictureBox(i+1)];
 Plot2 = jrn2 [PictureBox(i+1)];
 TitleTxt = jrn1 [TextEditBox((i*3)+1)] << get text;
 
 Show (TitleTxt);
  
 MylpBox = Lineup Box (N Col (4));
 
 SPRI = SpacerBox (size (50,50)) << get picture;
 
 MylpBox << Append (SPRI);
 MylpBox << Append (Plot1);
 MylpBox << Append (Plot2);
 MylpBox << Append (SPRI);
 
 PLOTS  = MylpBox << get picture;
 
 nw = New Window ("SERENE UC",
     OutlineBox(TitleTxt,
       
       PictureBox (PLOTS)
        
       )
      
     );
  
 nw << Save Presentation ("C:\Users\sornstr\Desktop\TEMP PNG\NEW OUTPUT.pptx", Append, Outline Titles (Top Left));
 
 nw << close window;
 
); 

open ("C:\Users\sornstr\Desktop\TEMP PNG\NEW OUTPUT.pptx");

感謝您的幫助。

 

真摯地，

 

TS

 

回复：JSL 速度優化：避免重複調用“保存演示文稿”（“文件”、追加）

JMP 社區您好，

 

我解決了我的問題：我只需要創建一個新的日誌，在其中放置複合圖（見下文）。

 

Names Default to Here (1);

jrn1 = Get Window("FIRST_JOURNAL");
jrn2 = Get Window("SECOND_JOURNAL");
jrn_out = New Window ("COMPIL",<< journal);


For (i = 0, i <3, i++, 
 
 Plot1 = jrn1 [PictureBox(i+1)];
 Plot2 = jrn2 [PictureBox(i+1)];
 TitleTxt = jrn1 [TextEditBox((i*3)+1)] << get text;
 
 Show (TitleTxt);
  
 MylpBox = Lineup Box (N Col (4));
 
 SPRI = SpacerBox (size (50,50)) << get picture;
 
 MylpBox << Append (SPRI);
 MylpBox << Append (Plot1);
 MylpBox << Append (Plot2);
 MylpBox << Append (SPRI);
 
 PLOTS  = MylpBox << get picture;
 
 nw = New Window ("SERENE UC",
     OutlineBox(TitleTxt,
       
       PictureBox (PLOTS)
        
       )
      
     );
  

 jrn_out << Append (nw);
 nw << close window;
 
); 
jrn_out << Save Presentation ("C:\Users\sornstr\Desktop\TEMP PNG\NEW OUTPUT.pptx", Template ("C:\Users\sornstr\Desktop\JMP Scripts\SANDBOX\JMPExportTemplate_TS.pptx"), Outline Titles (Top Left));
open ("C:\Users\sornstr\Desktop\TEMP PNG\NEW OUTPUT.pptx");