253788_es-ES

liliconcom

Optimización JSL para la velocidad: evitar llamadas repetidas para guardar presentación ("Archivo", Agregar)

Hola comunidad JMP:

 

Estoy progresando en mi intento de generar diapositivas de PowerPoint ensambladas a partir de los Plots almacenados en archivos de múltiples diarios (JRN).

El siguiente script produce el resultado correcto pero es bastante lento debido a las repetidas llamadas a << Guardar presentación ("nombre_archivo", Adjuntar )

Creo que sería mucho más rápido agregar las diferentes parcelas en un contenedor maestro (nueva ventana o nuevo diario) y luego usar Guardar presentación solo una vez para todo el contenedor maestro. ¿Cómo podría hacer esto? Me estoy confundiendo un poco sobre el anidamiento de diferentes estructuras de visualización.

Names Default to Here (1);

dummy = H List Box ();

dummy << Save Presentation ("C:\Users\sornstr\Desktop\TEMP PNG\NEW OUTPUT.pptx", Template ("C:\Users\sornstr\Desktop\JMP Scripts\SANDBOX\JMPExportTemplate_TS.pptx"), Outline Titles (Top Left));

jrn1 = Get Window("Journal: FIRST JOURNAL");
jrn2 = Get Window("Journal: SECOND JOURNAL");



For (i = 0, i <50, i++, 
 
 Plot1 = jrn1 [PictureBox(i+1)];
 Plot2 = jrn2 [PictureBox(i+1)];
 TitleTxt = jrn1 [TextEditBox((i*3)+1)] << get text;
 
 Show (TitleTxt);
  
 MylpBox = Lineup Box (N Col (4));
 
 SPRI = SpacerBox (size (50,50)) << get picture;
 
 MylpBox << Append (SPRI);
 MylpBox << Append (Plot1);
 MylpBox << Append (Plot2);
 MylpBox << Append (SPRI);
 
 PLOTS  = MylpBox << get picture;
 
 nw = New Window ("SERENE UC",
     OutlineBox(TitleTxt,
       
       PictureBox (PLOTS)
        
       )
      
     );
  
 nw << Save Presentation ("C:\Users\sornstr\Desktop\TEMP PNG\NEW OUTPUT.pptx", Append, Outline Titles (Top Left));
 
 nw << close window;
 
); 

open ("C:\Users\sornstr\Desktop\TEMP PNG\NEW OUTPUT.pptx");

Gracias por tu ayuda.

 

Sinceramente,

 

TS

 

Re: JSL Optimización para la velocidad: Evitar llamadas repetidas para Guardar Presentación ("Archivo", Agregar)

Hola comunidad JMP,

 

Resolví mi problema: solo necesitaba crear un nuevo diario en el que colocara los gráficos compuestos (ver más abajo).

 

Names Default to Here (1);

jrn1 = Get Window("FIRST_JOURNAL");
jrn2 = Get Window("SECOND_JOURNAL");
jrn_out = New Window ("COMPIL",<< journal);


For (i = 0, i <3, i++, 
 
 Plot1 = jrn1 [PictureBox(i+1)];
 Plot2 = jrn2 [PictureBox(i+1)];
 TitleTxt = jrn1 [TextEditBox((i*3)+1)] << get text;
 
 Show (TitleTxt);
  
 MylpBox = Lineup Box (N Col (4));
 
 SPRI = SpacerBox (size (50,50)) << get picture;
 
 MylpBox << Append (SPRI);
 MylpBox << Append (Plot1);
 MylpBox << Append (Plot2);
 MylpBox << Append (SPRI);
 
 PLOTS  = MylpBox << get picture;
 
 nw = New Window ("SERENE UC",
     OutlineBox(TitleTxt,
       
       PictureBox (PLOTS)
        
       )
      
     );
  

 jrn_out << Append (nw);
 nw << close window;
 
); 
jrn_out << Save Presentation ("C:\Users\sornstr\Desktop\TEMP PNG\NEW OUTPUT.pptx", Template ("C:\Users\sornstr\Desktop\JMP Scripts\SANDBOX\JMPExportTemplate_TS.pptx"), Outline Titles (Top Left));
open ("C:\Users\sornstr\Desktop\TEMP PNG\NEW OUTPUT.pptx");