253788_it-IT

liliconcom

Ottimizzazione JSL per la velocità: evitare chiamate ripetute per salvare la presentazione ("File", Aggiungi)

Ciao comunità JMP,

 

Sto facendo alcuni progressi nel mio tentativo di generare diapositive PowerPoint assemblate dai grafici archiviati in file JRN (Multiple Journal).

Lo script seguente produce l'output corretto ma è molto probabilmente lento a causa delle ripetute chiamate a << Salva presentazione ("nome_file", Aggiungere ).

Penso che sarebbe molto più veloce aggregare i diversi grafici in un contenitore principale (nuova finestra o nuovo diario) e quindi utilizzare Salva presentazione solo una volta per l'intero contenitore principale. Come potrei farlo: mi sto un po' confondendo sull'annidamento di diverse strutture di visualizzazione.

Names Default to Here (1);

dummy = H List Box ();

dummy << Save Presentation ("C:\Users\sornstr\Desktop\TEMP PNG\NEW OUTPUT.pptx", Template ("C:\Users\sornstr\Desktop\JMP Scripts\SANDBOX\JMPExportTemplate_TS.pptx"), Outline Titles (Top Left));

jrn1 = Get Window("Journal: FIRST JOURNAL");
jrn2 = Get Window("Journal: SECOND JOURNAL");



For (i = 0, i <50, i++, 
 
 Plot1 = jrn1 [PictureBox(i+1)];
 Plot2 = jrn2 [PictureBox(i+1)];
 TitleTxt = jrn1 [TextEditBox((i*3)+1)] << get text;
 
 Show (TitleTxt);
  
 MylpBox = Lineup Box (N Col (4));
 
 SPRI = SpacerBox (size (50,50)) << get picture;
 
 MylpBox << Append (SPRI);
 MylpBox << Append (Plot1);
 MylpBox << Append (Plot2);
 MylpBox << Append (SPRI);
 
 PLOTS  = MylpBox << get picture;
 
 nw = New Window ("SERENE UC",
     OutlineBox(TitleTxt,
       
       PictureBox (PLOTS)
        
       )
      
     );
  
 nw << Save Presentation ("C:\Users\sornstr\Desktop\TEMP PNG\NEW OUTPUT.pptx", Append, Outline Titles (Top Left));
 
 nw << close window;
 
); 

open ("C:\Users\sornstr\Desktop\TEMP PNG\NEW OUTPUT.pptx");

Grazie per l'aiuto.

 

Cordiali saluti,

 

TS

 

Re: Ottimizzazione JSL per la velocità: evitare chiamate ripetute per salvare la presentazione ("File", Aggiungi)

Ciao comunità JMP,

 

Ho risolto il mio problema: avevo solo bisogno di creare un nuovo diario in cui ho inserito i grafici compositi (vedi sotto).

 

Names Default to Here (1);

jrn1 = Get Window("FIRST_JOURNAL");
jrn2 = Get Window("SECOND_JOURNAL");
jrn_out = New Window ("COMPIL",<< journal);


For (i = 0, i <3, i++, 
 
 Plot1 = jrn1 [PictureBox(i+1)];
 Plot2 = jrn2 [PictureBox(i+1)];
 TitleTxt = jrn1 [TextEditBox((i*3)+1)] << get text;
 
 Show (TitleTxt);
  
 MylpBox = Lineup Box (N Col (4));
 
 SPRI = SpacerBox (size (50,50)) << get picture;
 
 MylpBox << Append (SPRI);
 MylpBox << Append (Plot1);
 MylpBox << Append (Plot2);
 MylpBox << Append (SPRI);
 
 PLOTS  = MylpBox << get picture;
 
 nw = New Window ("SERENE UC",
     OutlineBox(TitleTxt,
       
       PictureBox (PLOTS)
        
       )
      
     );
  

 jrn_out << Append (nw);
 nw << close window;
 
); 
jrn_out << Save Presentation ("C:\Users\sornstr\Desktop\TEMP PNG\NEW OUTPUT.pptx", Template ("C:\Users\sornstr\Desktop\JMP Scripts\SANDBOX\JMPExportTemplate_TS.pptx"), Outline Titles (Top Left));
open ("C:\Users\sornstr\Desktop\TEMP PNG\NEW OUTPUT.pptx");