253788_de-DE

liliconcom

JSL-Optimierung für Geschwindigkeit: Vermeidung wiederholter Aufrufe zum Speichern der Präsentation ("Datei", Anhängen)

Hallo JMP-Community,

 

Ich mache einige Fortschritte bei meinem Versuch, PowerPoint-Folien zu erstellen, die aus den in mehreren Zeitschriftendateien (JRN) gespeicherten Diagrammen zusammengesetzt sind.

Das folgende Skript erzeugt die richtige Ausgabe, ist aber höchstwahrscheinlich aufgrund der wiederholten Aufrufe von << Präsentation speichern ("Dateiname", Anhängen ).

Ich denke, es wäre viel schneller, die verschiedenen Plots in einem Master-Container (neues Fenster oder neues Journal) zusammenzufassen und dann Save Presentation nur einmal für den gesamten Master-Container zu verwenden. Wie könnte ich das tun: Ich bin etwas verwirrt über die Verschachtelung verschiedener Anzeigestrukturen.

Names Default to Here (1);

dummy = H List Box ();

dummy << Save Presentation ("C:\Users\sornstr\Desktop\TEMP PNG\NEW OUTPUT.pptx", Template ("C:\Users\sornstr\Desktop\JMP Scripts\SANDBOX\JMPExportTemplate_TS.pptx"), Outline Titles (Top Left));

jrn1 = Get Window("Journal: FIRST JOURNAL");
jrn2 = Get Window("Journal: SECOND JOURNAL");



For (i = 0, i <50, i++, 
 
 Plot1 = jrn1 [PictureBox(i+1)];
 Plot2 = jrn2 [PictureBox(i+1)];
 TitleTxt = jrn1 [TextEditBox((i*3)+1)] << get text;
 
 Show (TitleTxt);
  
 MylpBox = Lineup Box (N Col (4));
 
 SPRI = SpacerBox (size (50,50)) << get picture;
 
 MylpBox << Append (SPRI);
 MylpBox << Append (Plot1);
 MylpBox << Append (Plot2);
 MylpBox << Append (SPRI);
 
 PLOTS  = MylpBox << get picture;
 
 nw = New Window ("SERENE UC",
     OutlineBox(TitleTxt,
       
       PictureBox (PLOTS)
        
       )
      
     );
  
 nw << Save Presentation ("C:\Users\sornstr\Desktop\TEMP PNG\NEW OUTPUT.pptx", Append, Outline Titles (Top Left));
 
 nw << close window;
 
); 

open ("C:\Users\sornstr\Desktop\TEMP PNG\NEW OUTPUT.pptx");

Danke für Ihre Hilfe.

 

Aufrichtig,

 

TS

 

Betreff: JSL-Optimierung für Geschwindigkeit: Vermeiden wiederholter Aufrufe zum Speichern der Präsentation ("Datei", Anhängen)

Hallo JMP-Gemeinde,

 

Ich habe mein Problem gelöst: Ich musste nur ein neues Journal erstellen, in dem ich die zusammengesetzten Diagramme platzierte (siehe unten).

 

Names Default to Here (1);

jrn1 = Get Window("FIRST_JOURNAL");
jrn2 = Get Window("SECOND_JOURNAL");
jrn_out = New Window ("COMPIL",<< journal);


For (i = 0, i <3, i++, 
 
 Plot1 = jrn1 [PictureBox(i+1)];
 Plot2 = jrn2 [PictureBox(i+1)];
 TitleTxt = jrn1 [TextEditBox((i*3)+1)] << get text;
 
 Show (TitleTxt);
  
 MylpBox = Lineup Box (N Col (4));
 
 SPRI = SpacerBox (size (50,50)) << get picture;
 
 MylpBox << Append (SPRI);
 MylpBox << Append (Plot1);
 MylpBox << Append (Plot2);
 MylpBox << Append (SPRI);
 
 PLOTS  = MylpBox << get picture;
 
 nw = New Window ("SERENE UC",
     OutlineBox(TitleTxt,
       
       PictureBox (PLOTS)
        
       )
      
     );
  

 jrn_out << Append (nw);
 nw << close window;
 
); 
jrn_out << Save Presentation ("C:\Users\sornstr\Desktop\TEMP PNG\NEW OUTPUT.pptx", Template ("C:\Users\sornstr\Desktop\JMP Scripts\SANDBOX\JMPExportTemplate_TS.pptx"), Outline Titles (Top Left));
open ("C:\Users\sornstr\Desktop\TEMP PNG\NEW OUTPUT.pptx");