253788_fr-FR

liliconcom

Optimisation JSL pour la vitesse : Éviter les appels répétés pour enregistrer la présentation ("Fichier", Append)

Salut la communauté JMP,

 

Je progresse dans ma tentative de générer des diapositives PowerPoint assemblées à partir des tracés stockés dans plusieurs fichiers de journaux (JRN).

Le script suivant produit la bonne sortie, mais il est assez lent, probablement en raison des appels répétés à << Enregistrer la présentation ("file_name", Ajouter ).

Je pense qu'il serait beaucoup plus rapide d'agréger les différentes parcelles dans un conteneur principal (nouvelle fenêtre ou nouveau journal), puis d'utiliser Enregistrer la présentation une seule fois pour l'ensemble du conteneur principal. Comment pourrais-je faire cela : je suis un peu confus quant à l'imbrication des différentes structures d'affichage.

Names Default to Here (1);

dummy = H List Box ();

dummy << Save Presentation ("C:\Users\sornstr\Desktop\TEMP PNG\NEW OUTPUT.pptx", Template ("C:\Users\sornstr\Desktop\JMP Scripts\SANDBOX\JMPExportTemplate_TS.pptx"), Outline Titles (Top Left));

jrn1 = Get Window("Journal: FIRST JOURNAL");
jrn2 = Get Window("Journal: SECOND JOURNAL");



For (i = 0, i <50, i++, 
 
 Plot1 = jrn1 [PictureBox(i+1)];
 Plot2 = jrn2 [PictureBox(i+1)];
 TitleTxt = jrn1 [TextEditBox((i*3)+1)] << get text;
 
 Show (TitleTxt);
  
 MylpBox = Lineup Box (N Col (4));
 
 SPRI = SpacerBox (size (50,50)) << get picture;
 
 MylpBox << Append (SPRI);
 MylpBox << Append (Plot1);
 MylpBox << Append (Plot2);
 MylpBox << Append (SPRI);
 
 PLOTS  = MylpBox << get picture;
 
 nw = New Window ("SERENE UC",
     OutlineBox(TitleTxt,
       
       PictureBox (PLOTS)
        
       )
      
     );
  
 nw << Save Presentation ("C:\Users\sornstr\Desktop\TEMP PNG\NEW OUTPUT.pptx", Append, Outline Titles (Top Left));
 
 nw << close window;
 
); 

open ("C:\Users\sornstr\Desktop\TEMP PNG\NEW OUTPUT.pptx");

Merci de votre aide.

 

Sincèrement,

 

TS

 

Re : Optimisation JSL pour la vitesse : Éviter les appels répétés pour enregistrer la présentation ("Fichier", Append)

Salut la communauté JMP,

 

J'ai résolu mon problème : j'avais juste besoin de créer un nouveau journal dans lequel j'ai placé les tracés composites (voir ci-dessous).

 

Names Default to Here (1);

jrn1 = Get Window("FIRST_JOURNAL");
jrn2 = Get Window("SECOND_JOURNAL");
jrn_out = New Window ("COMPIL",<< journal);


For (i = 0, i <3, i++, 
 
 Plot1 = jrn1 [PictureBox(i+1)];
 Plot2 = jrn2 [PictureBox(i+1)];
 TitleTxt = jrn1 [TextEditBox((i*3)+1)] << get text;
 
 Show (TitleTxt);
  
 MylpBox = Lineup Box (N Col (4));
 
 SPRI = SpacerBox (size (50,50)) << get picture;
 
 MylpBox << Append (SPRI);
 MylpBox << Append (Plot1);
 MylpBox << Append (Plot2);
 MylpBox << Append (SPRI);
 
 PLOTS  = MylpBox << get picture;
 
 nw = New Window ("SERENE UC",
     OutlineBox(TitleTxt,
       
       PictureBox (PLOTS)
        
       )
      
     );
  

 jrn_out << Append (nw);
 nw << close window;
 
); 
jrn_out << Save Presentation ("C:\Users\sornstr\Desktop\TEMP PNG\NEW OUTPUT.pptx", Template ("C:\Users\sornstr\Desktop\JMP Scripts\SANDBOX\JMPExportTemplate_TS.pptx"), Outline Titles (Top Left));
open ("C:\Users\sornstr\Desktop\TEMP PNG\NEW OUTPUT.pptx");