252795_es-ES

liliconcom

Script para ejecutar fórmulas complicadas en nuevas columnas

Intentando descubrir cómo escribir una fórmula complicada a partir de un ajuste de curva usando la fórmula predictiva.  Es sencillo si todos los datos se agrupan y solo hay una fórmula, sin embargo, si divido los datos en conjuntos más pequeños, me quedo atascado con las secuencias de comandos.  Puedo hacerlo de forma interactiva, pero tengo muchas tablas de datos diferentes, por lo que hacerlo manualmente será muy tedioso.  (Gracias por adelantado)

 

He usado datos de ejemplo JMP Big Class como ejemplo 

dt = Current Data Table(); //Big Class active 

biv = Bivariate(
  Y( :height ),
  X( :weight ),
  by( :sex, :age ),
  Fit Special( xTran( "Log" ), {Line Color( {212, 73, 88} )}, save predicteds )
);
biv << (curve[1] << save predicteds);
Column( N Cols( dt ) ) << set name( "Predicted Values" );

dt << NewColumn("Weight_150", set each value(150));
dt << NewColumn("Weight_180", set each value(180));

// Stuck here want to use the "Predicted Values" formula on the new weights columns added
// basically need a script to copy over formula from "Predicted Values" which is now very complicated
// and replace  "weight" with "weight_150" and "weight_180" in the formula, creating two new columns&nbsp;<BR />//&nbsp;extrapolated&nbsp;values&nbsp;at&nbsp;150&nbsp;and&nbsp;180

Re: Script para ejecutar fórmulas complicadas en nuevas columnas

Si entiendo correctamente, aquí hay una manera. A este enfoque no le importa lo complicada que sea la fórmula.

NamesDefaultToHere(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp"); //Big Class active 

biv = dt << Bivariate(
     Y( :height ),
     X( :weight ),
     by( :sex, :age ),
     Fit Special( xTran( "Log" ), {Line Color( {212, 73, 88} )}, save predicteds )
   );
biv << (curve[1] << save predicteds);
Column(dt,  N Cols( dt ) ) << set name( "Predicted Values" );

dt << NewColumn("Weight_150", set each value(150));
dt << NewColumn("Weight_180", set each value(180));
myFormula = Column(dt, "Predicted Values") << getFormula;

// Stuck here want to use the "Predicted Values" formula on the new weights columns added
// basically need a script to copy over formula from "Predicted Values" which is now very complicated
// and replace  "weight" with "weight_150" and "weight_180" in the formula, creating two new columns
// extrapolated values at 150 and 180
myFormula150 = Substitute(NameExpr(myFormula), Expr(:weight), Expr(:weight_150));
dt << NewColumn( "Predicted Values 150" );
addFormula = Expr(Column(dt, "Predicted Values 150") << setFormula(formulaTBD));
SubstituteInto(addFormula, Expr(formulaTBD), NameExpr(myFormula150));
addFormula;

myFormula180 = Substitute(NameExpr(myFormula), Expr(:weight), Expr(:weight_180));
dt << NewColumn( "Predicted Values 180" );
addFormula = Expr(Column(dt, "Predicted Values 180") << setFormula(formulaTBD));
SubstituteInto(addFormula, Expr(formulaTBD), NameExpr(myFormula180));
addFormula;

dt << runFormulas;