252795_ja-JP

liliconcom

新しい列で複雑な数式を実行するスクリプト

予測式を使用して曲線近似から複雑な式をスクリプト化する方法を見つけようとしています。  すべてのデータがひとまとめにされていて、式が1つしかない場合は簡単ですが、データを小さなセットに分割すると、スクリプトにこだわってしまいます。  インタラクティブに行うことはできますが、多くの異なるデータテーブルがあるため、手動で行うのは非常に面倒です。  （前もって感謝します）

 

サンプルとしてJMPサンプルデータBig Classを使用しました 

dt = Current Data Table(); //Big Class active 

biv = Bivariate(
  Y( :height ),
  X( :weight ),
  by( :sex, :age ),
  Fit Special( xTran( "Log" ), {Line Color( {212, 73, 88} )}, save predicteds )
);
biv << (curve[1] << save predicteds);
Column( N Cols( dt ) ) << set name( "Predicted Values" );

dt << NewColumn("Weight_150", set each value(150));
dt << NewColumn("Weight_180", set each value(180));

// Stuck here want to use the "Predicted Values" formula on the new weights columns added
// basically need a script to copy over formula from "Predicted Values" which is now very complicated
// and replace  "weight" with "weight_150" and "weight_180" in the formula, creating two new columns&nbsp;<BR />//&nbsp;extrapolated&nbsp;values&nbsp;at&nbsp;150&nbsp;and&nbsp;180

再：新しい列で複雑な数式を実行するスクリプト

私が正しく理解しているなら、ここに一つの方法があります。このアプローチは、式がどれほど複雑であるかを気にしません。

NamesDefaultToHere(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp"); //Big Class active 

biv = dt << Bivariate(
     Y( :height ),
     X( :weight ),
     by( :sex, :age ),
     Fit Special( xTran( "Log" ), {Line Color( {212, 73, 88} )}, save predicteds )
   );
biv << (curve[1] << save predicteds);
Column(dt,  N Cols( dt ) ) << set name( "Predicted Values" );

dt << NewColumn("Weight_150", set each value(150));
dt << NewColumn("Weight_180", set each value(180));
myFormula = Column(dt, "Predicted Values") << getFormula;

// Stuck here want to use the "Predicted Values" formula on the new weights columns added
// basically need a script to copy over formula from "Predicted Values" which is now very complicated
// and replace  "weight" with "weight_150" and "weight_180" in the formula, creating two new columns
// extrapolated values at 150 and 180
myFormula150 = Substitute(NameExpr(myFormula), Expr(:weight), Expr(:weight_150));
dt << NewColumn( "Predicted Values 150" );
addFormula = Expr(Column(dt, "Predicted Values 150") << setFormula(formulaTBD));
SubstituteInto(addFormula, Expr(formulaTBD), NameExpr(myFormula150));
addFormula;

myFormula180 = Substitute(NameExpr(myFormula), Expr(:weight), Expr(:weight_180));
dt << NewColumn( "Predicted Values 180" );
addFormula = Expr(Column(dt, "Predicted Values 180") << setFormula(formulaTBD));
SubstituteInto(addFormula, Expr(formulaTBD), NameExpr(myFormula180));
addFormula;

dt << runFormulas;