252795_fr-FR

liliconcom

Script pour exécuter une formule compliquée sur de nouvelles colonnes

Essayer de comprendre comment écrire une formule compliquée à partir d'un ajustement de courbe à l'aide de la formule prédictive.  C'est simple si toutes les données sont regroupées et qu'il n'y a qu'une seule formule, mais si je divise les données en ensembles plus petits, je suis coincé avec les scripts.  Je peux le faire de manière interactive, mais j'ai de nombreuses tables de données différentes, donc le faire manuellement deviendra très fastidieux.  (Merci d'avance)

 

J'ai utilisé l'exemple de données JMP Big Class comme exemple 

dt = Current Data Table(); //Big Class active 

biv = Bivariate(
  Y( :height ),
  X( :weight ),
  by( :sex, :age ),
  Fit Special( xTran( "Log" ), {Line Color( {212, 73, 88} )}, save predicteds )
);
biv << (curve[1] << save predicteds);
Column( N Cols( dt ) ) << set name( "Predicted Values" );

dt << NewColumn("Weight_150", set each value(150));
dt << NewColumn("Weight_180", set each value(180));

// Stuck here want to use the "Predicted Values" formula on the new weights columns added
// basically need a script to copy over formula from "Predicted Values" which is now very complicated
// and replace  "weight" with "weight_150" and "weight_180" in the formula, creating two new columns&nbsp;<BR />//&nbsp;extrapolated&nbsp;values&nbsp;at&nbsp;150&nbsp;and&nbsp;180

Re: Script pour exécuter une formule compliquée sur de nouvelles colonnes

Si je comprends bien, voici une façon. Cette approche ne se soucie pas de la complexité de la formule.

NamesDefaultToHere(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp"); //Big Class active 

biv = dt << Bivariate(
     Y( :height ),
     X( :weight ),
     by( :sex, :age ),
     Fit Special( xTran( "Log" ), {Line Color( {212, 73, 88} )}, save predicteds )
   );
biv << (curve[1] << save predicteds);
Column(dt,  N Cols( dt ) ) << set name( "Predicted Values" );

dt << NewColumn("Weight_150", set each value(150));
dt << NewColumn("Weight_180", set each value(180));
myFormula = Column(dt, "Predicted Values") << getFormula;

// Stuck here want to use the "Predicted Values" formula on the new weights columns added
// basically need a script to copy over formula from "Predicted Values" which is now very complicated
// and replace  "weight" with "weight_150" and "weight_180" in the formula, creating two new columns
// extrapolated values at 150 and 180
myFormula150 = Substitute(NameExpr(myFormula), Expr(:weight), Expr(:weight_150));
dt << NewColumn( "Predicted Values 150" );
addFormula = Expr(Column(dt, "Predicted Values 150") << setFormula(formulaTBD));
SubstituteInto(addFormula, Expr(formulaTBD), NameExpr(myFormula150));
addFormula;

myFormula180 = Substitute(NameExpr(myFormula), Expr(:weight), Expr(:weight_180));
dt << NewColumn( "Predicted Values 180" );
addFormula = Expr(Column(dt, "Predicted Values 180") << setFormula(formulaTBD));
SubstituteInto(addFormula, Expr(formulaTBD), NameExpr(myFormula180));
addFormula;

dt << runFormulas;