252717_ko-KR

liliconcom

공통 열 이름을 일치시켜 두 테이블 조인

안녕,

아래와 같이 두 개의 테이블이 있습니다.

1 번 테이블 :

이름	부분	주제
아담	ㅏ	수학
단발	ㅏ	과학
크리스	비	영어

 

표2:

 

이름	부분	점수
아담	ㅏ	80
단발	ㅏ	90
크리스	비	84

 

jsl에서 두 테이블을 모두 조인하고 다음 출력 테이블을 얻고 싶지만 일치하는 열 이름을 명시적으로 제공하고 싶지 않습니다. 일치하는 열은 두 테이블에서 동일한 열 이름을 가진 열입니다. 일치하는 열은 다를 수 있습니다. 2개(표시된 예와 같이) 또는 3개 이상일 수 있지만 일치하는 열은 동일한 열 이름을 갖습니다.

산출:

이름	부분	주제	점수
아담	ㅏ	수학	80
단발	ㅏ	과학	90
크리스	비	영어	84

 

감사

Re: 공통 열 이름을 일치시켜 두 테이블 조인

이렇게 해야 합니다.

 

DT1 = New Table("DT1",
 << Add Rows(3),
 << New Column("Name", character, Values({"Adam","Bob","Chris"})),
 << New Column("Section", character, Values({"A","A","B"})),
 << New Column("Subject", character, Values({"Math","Science","English"}))
);
DT2 = New Table("DT2",
 << Add Rows(3),
 << New Column("Name", character, Values({"Adam","Bob","Chris"})),
 << New Column("Section", character, Values({"A","A","B"})),
 << New Column("Score", numeric,continous, Values({80,90,84}))
);
LSTcols1 = DT1 << Get Column Names(string);
LSTcols2 = DT2 << Get Column Names(string);

STRjoinCols = "";

For(LVC=1,LVC<=N Items(LSTcols1),LVC++,
 STRcol = LSTcols1[LVC];
 If(
  Contains(LSTCols2,STRcol)
 ,
  If(
   STRjoinCols == ""
  ,
   STRjoinCols = ":"||STRcol||"==:"||STRcol
  ,
   STRjoinCols = STRjoinCols||", :"||STRcol||"==:"||STRcol
  );
 );
);
expr = Eval Insert(
 "\[
 DT3 = DT1 << Join(
    With( DT2 ),
    Merge Same Name Columns,
    Match Flag( 0 ),
    By Matching Columns( ^STRjoinCols^ ),
    Drop multiples( 0, 0 ),
    Include Nonmatches( 0, 0 ),
    Preserve main table order( 0 ),
    Output Table( "DT3" )
 );
 ]\"
);
Eval( Parse( expr ) );