how to replicate each run once at time for DSD

Alhelali

i want to create code that helps me to replicate selected run in full factorial design. 

For example if i have full factorial design with 4 factors and 16 runs. i want to select one run to be replicated to generate a new matrix. i need do looping to generate 16 matrices based on the original full factorial matrix.  

Mark_Bailey

Please clarify a few points.

 

1. You want to create an augmented design by replicating one run?
2. You want to augment the original design once for for every run in the original design?
3. Do you want the new designs in their own data table?

Assuming the answer to all these questions is yes, then this script illustrates how it might be done.

 

Names Default to Here( 1 );

// set up example design
design = DOE(
	Full Factorial Design,
	{Add Response( Maximize, "Y", ., ., . ),
	Add Factor( Continuous, {-1, 1}, "X1", 0 ),
	Add Factor( Continuous, {-1, 1}, "X2", 0 ),
	Add Factor( Continuous, {-1, 1}, "X3", 0 ),
	Add Factor( Continuous, {-1, 1}, "X4", 0 ), Set Random Seed( 1338093688 ),
	Make Design, Simulate Responses( 0 )}
);

dt = design << Make Table;

design << Close Window;

// assume that orginal design by JMP is available as current data table
factor = dt << Get Column Names( Numeric, String );
Remove From( factor );

// obtain design and remove response column (last data column)
design = dt << Get As Matrix;
design[0,NCol(design)] = [];

// iterate over the rows of the original table
nr = N Row( design );
For( i = 1, i <= nr, i++,
	augmented = design |/ design[i,0];
	As Table( augmented, << Column Names( factor ) );
);

 

The initial part of the script creates an example. In practice, delete this portion of the script. Create the design with JMP platform and make the table. Then run the remainder of the script.