251633_es-ES

liliconcom

recorrer los nombres de columna y hacer un ajuste bivariado con ciertos y la pendiente de salida y el valor R cuadrado

La publicación relevante está aquí,

Tengo muchas columnas y no quiero incluir algunas en el análisis. Así que necesito recorrer los nombres de las columnas y elegir los que necesito y hacer un ajuste bivariado.

 

Entonces, siguiendo la solución en la publicación anterior

 

yo hice

 

NamesDefaultToHere(1);

dt = Open("$SAMPLE_DATA/Fishing.jmp");


colList = dt << get column names( string );

For( i = 1, i <= N Items( colList ), i++,
 If( ! Contains( colList[i], "Validation") & ! Contains( colList[i], "People") ,
 
 biv = Bivariate(invisible,
 Y( :Fish Caught ),
 X( :i),
 Fit Line( {Line Color( "Medium Dark Red" )} ),
 By( :Validation )
))
 
 dtR2 = report(biv[1])["Summary of Fit"][tablebox(1)]<< make combined data table;

dtR2 = report(biv[1])["Summary of Fit"][tablebox(1)]<< make combined data table;
dtSlope = report(biv[1])["Parameter Estimates"][tablebox(1)]<< make combined data table (invisible);
dtR2 << select where(:Column 1 != "RSquare");
dtR2 << delete rows;
dtR2:Column 2 << set name("RSquare");
dtR2 << delete Columns({"Validation 2","Column 1"}); 

dtSlope << select where(:Term == "Intercept");
dtSlope << delete rows;
dtSlope:Estimate << set name( "Slope");
dtSlope << delete columns({"Validation 2","Term","~Bias","Std Error","t Ratio","Prob>|t|"});

// Put the data together
dtR2 << Update(
 With( dtSlope ),
 Match Columns( :Validation = :Validation, :X = :X, :Y = :Y )
);

// Clean up the items not needed
close(dtSlope, nosave);
window("Fishing - Bivariate of Fish Caught") << close window;
);

pero parece que no estoy seguro de cómo implementar esto correctamente.

Re: recorra los nombres de las columnas y realice ajustes bivariados con ciertos y la pendiente de salida y el valor R cuadrado

¿Puede alguien del personal de Jmp ayudarme con este problema?

Re: recorra los nombres de las columnas y realice ajustes bivariados con ciertos y la pendiente de salida y el valor R cuadrado

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA/Fishing.jmp" );

col = dt << Get Column Names( Numeric, String );

For( c = N Items( col ), c > 0 , c--,
 If( col[c] == "Fish Caught", Remove From( col, c ) );
 If( col[c] == "Validation", Remove From( col, c ) );
 If( col[c] == "People", Remove From( col, c ) );
);

biv = dt << Bivariate(
 Y( :Fish Caught ),
 X( Eval( col ) ),
 By( :Validation ),
 Fit Line
);

biv rep = biv << Report;

summary dt = biv rep[1]["Summary of Fit"][TableBox(1)] << Make Combined Data Table;
parameter dt = biv rep[1]["Parameter Estimates"][TableBox(1)] << Make Combined Data Table;

Wait( 0 );

biv << Close Window;

Column( summary dt, 6 ) << Set Name( "RSquare" );
summary dt
 << Select Where( Contains( :Column 1[], "RSquare" ) & Not( Contains( :Column 1[], "Adj" ) ) )
 << Invert Row Selection
 << Delete Rows
 << Delete Columns( { "Y", "Validation 2", "Column 1" } );

Column( parameter dt, 7 ) << Set Name( "Slope" );
parameter dt
 << Select Where( Contains( :Term[], "Intercept" ) )
 << Delete Rows
 << Delete Columns( { "Y", "Validation 2", "Term", "~Bias", "Std Error", "t Ratio", "Prob>|t|" } );

summary dt << Join(
 With(parameter dt ),
 Select( :Validation, :X, :RSquare ),
 SelectWith( :Slope ),
 By Row Number
);

Close( summary dt, No Save );
Close( parameter dt, No Save );

Re: recorra los nombres de las columnas y realice ajustes bivariados con ciertos y la pendiente de salida y el valor R cuadrado

¿Te ayudó esta solución?

Re: recorra los nombres de las columnas y realice ajustes bivariados con ciertos y la pendiente de salida y el valor R cuadradosí marca, perdón por la demora