250563_it-IT

liliconcom

avvio automatico di 2 tabelle simultanee

Mi chiedo se qualcuno sa come avviare o simulare due tabelle separate contemporaneamente.  Per esempio.  

Names default to here(1);
dt = open("$SAMPLE_DATA\Big Class.jmp");
dt << Fit Model(
 Y( :height ),
 Effects( :weight, :age, :weight * :age ),
 Personality( "Generalized Regression" ),
 Generalized Distribution( "Normal" ),
 Run(
  Fit( Estimation Method( Lasso ), Validation Method( AICc ) )
 ),
);

Diciamo che voglio ottenere l'AICc dei valori per questo modello in un bootstrap e che si allineano con le stime di un bootstrap?

Posso semplicemente dare a entrambi lo stesso seme casuale? In tal caso, il bootstrap non richiederebbe il doppio del tempo? 

 

La mia ipotesi è che il bootstrap sia già multithread?  

Ri: bootstrapping 2 tabelle simultanee

Ciao Vince

Penso che questo script dovrebbe mostrarti come farlo. Non conosco un modo interattivo per farlo, ma è possibile utilizzare JSL per selezionare più colonne nel report e quindi inviare il messaggio Bootstrap a uno di essi. Il bootstrap viene quindi eseguito su tutte le tabelle con una colonna selezionata. Vedere l'esempio seguente per un modo per ottenere le stime dei parametri insieme al valore AICc corrispondente.

 

Names default to here(1);
dt = open("$SAMPLE_DATA\Big Class.jmp");
fm = dt << Fit Model(
 Y( :height ),
 Effects( :weight, :age, :weight * :age ),
 Personality( "Generalized Regression" ),
 Generalized Distribution( "Normal" ),
 Run(
  Fit( Estimation Method( Lasso ), Validation Method( AICc ) )
 ),
);

rpt = report(fm)["Normal Lasso with AICc Validation"];
rpt["Model Summary"][NumberColBox("")] << select;
rpt["Parameter Estimates for Original Predictors"][NumberColBox("Estimate")] << select;

randomreset(10373520);

dtlst = rpt["Parameter Estimates for Original Predictors"][NumberColBox("Estimate")] << Bootstrap(10, Fractional Weights(1));

dtlst[3] << Set Name("Measure Results");
dtlst[4] << Set Name("Parameter Estimates");

dtnew = dtlst[4] << Join(
 With( dtlst[3] ),
 By Matching Columns( :Name( "BootID•" ) = :Name( "BootID•" ) ),
 Select( dtlst[4] << Get Column Names ),
 Select With( :AICc ),
 Preserve Main Table Order( 1 ),
 Drop Multiples( 0, 0 )
)

Spero possa aiutare,

Michael

Ri: bootstrapping 2 tabelle simultanee

Fantastico, grazie per aver condiviso Michael!

Ri: bootstrapping 2 tabelle simultanee

Carino.  

Stavo cercando di farlo in modo interattivo, fico che posso semplicemente farlo tramite lo scripting.  

Non ho mai visto `random reset ()`, sembra che sia lo stesso di inviare random seed () a `bootstrap`.  Abbastanza bello  

 

Questo sembra fare esattamente quello che voglio.  

 

Ri: bootstrapping 2 tabelle simultaneePuoi fare la stessa cosa impostando il seme casuale all'interno della chiamata Bootstrap (). Random Reset () è solo la funzione che ti consente di impostare il seed interno per il generatore di numeri casuali in un momento specifico nel tuo script.