Combo Box <(tipstr)>

Niros

Hi,

When using Combo Box() it is possible to add a "tipstr" so that when the user hovers on the list options the relevant tip will appear:

 

 

MyList = {"Item1"("tip1"),
               "Item2"("tip2"), 
               "Item3"("tip3")};

P=Combo Box(MyList, num=P<<get();...);

 

 

The problem is that when I try to pass a variable I get the variable name as a tip, when I try to concatenate a string and a variable I get "concat" in return and if I try to cast the variable as string I get in return the function I used as a tip...

Any idea on how to solve this is welcome:)

 

I use JMP 12

JMP Online Documentation:

Combo Box({item <(tipstr)>, ...}, <script>)

Constructs a display box that is a drop-down list. Returns the display box object.

See Combo Box in the Scripting Guide for more information.

txnelson

Because what is passed to a Combo Box() is a List of items, the items within the list are not going to be processed(no calculations) before it is applied to the Combo Box(), so what is being passed to it, has to be exactly what is needed.  Here are a couple of ways to handle this

Names Default To Here( 1 );

displayList = {"One", "Two", "Three"};

tipList = {"This is One", "this is two", "this is three"};

finalList = {};
For( i = 1, i <= N Items( displayList ), i++,
	finalList[i] = Parse( "\!"" || displayList[i] || "\!"(\!"" || tipList[i] || "\!")" )
);


New Window( "Example",
	cb = Combo Box(
		Eval( finalList ),
		selection = cb << GetSelected();
		Print( "Selected: " || selection );
	)
);

Names Default To Here( 1 );
tipList = {"This is One", "this is two", "this is three"};

Eval(
	Substitute(
			Expr(
				New Window( "Example",
					cb = Combo Box(
						{"One"(__1__), "Two"(__2__), "Three"(__3__)},
						selection = cb << GetSelected();
						Print( "Selected: " || selection );
					)
				)
			),
		Expr( __1__ ), tipList[1],
		Expr( __2__ ), tipList[2],
		Expr( __3__ ), tipList[2]
	)
);