Graph Builder Add p Values dynamically: recommended workflow

Thierry_S

Hi JMP community,

 

I often need to annotate Graph Builder plots (~200) with the results of an analysis (e.g. p Values. Estimates). So far, I have mostly relied on manual annotations but I'm starting to be tired of this approach. I know how to add text dynamically via scripting but I have not figured out a good way to solve my specific problem (see below)

 

What would be your recommended workflow in the following case:

 

Graph Data: ~200 columns containing the Y values (~1,000 rows); X data define in 1 column, Overlay data in 1 column, yielding 200 plots

Analysis results: 1 row per Y value, columns containing the p Value, Estimates, and other possible analysis outputs.

Note: Automation has been challenging because the initial data is always slightly different from one batch to another. 

 

My main problem is that the graph data and analysis results tables are organized orthogonally (Y in columns vs. Y in rows) which would require transposing the result table, split the resulting table by analysis outputs (p Values, Estimates,...)  and connect the resulting table to the Graph Table. This does not seem very efficient so any suggestions would be welcome.

 

Thank you.

 

TS

 

ian_jmp

I'm sure everyone would approach this slightly differently. But if the two tables above are your starting point, then I would do something like this:

NamesDefaultToHere(1);

// Data tables
data = DataTable("Test WORKFLOW.jmp");
stats = DataTable("Test WORKFLOW RESULT TABLE.jmp");

// Template expression for Graph Builder with text annotation
gbExpr =
Expr(
	data << Graph Builder(
	Show Control Panel( 0 ),
	Variables( X( :X ), Y( yTBD ), Overlay( :Overlay ) ),
	Elements(Line(X, Y, Legend( 12 ), Error Interval( "None" ))),
	SendToReport(
		Dispatch(
			{},
			"Graph Builder",
			FrameBox,
			{Add Graphics Script( 2, Description( "Annotation" ), Text( {8, 0}, "interaction P Val: "||Char(Round(pValTBD, 3))))}
			)
		)
	)
);

// Loop over 'Y' variables
lub = LineUpBox(NCol(1));
for(c=3, c<=NCol(data), c++,
	yCol = Column(data, c);
	pVal = Column(stats, 2)[c-2];
	lub << append(Eval(Substitute(NameExpr(gbExpr), Expr(yTBD), yCol, Expr(pValTBD), pVal)));
	);

// Reports in a Journal
nw = NewWindow("Report", <<Journal, lub);

You should be able to develop this outline to suit your case. You could also try including some logic to place the annotation in a 'better' place. If you are not sure how it works, then see 'Help > Scripting Guide' and the JSL book.