248665_ko-KR

liliconcom

목록을 통해 여러 열의 셀에 색상을 지정할 수 없습니다

특정 열 이름 목록을 사용하여 셀 값별로 색상을 변경하기 위해 여러 열의 형식을 지정하려고하지만 코드의 목록의 첫 번째 열만 형식화합니다.

목록의 나머지 열을 형식화하려면 어떻게합니까?

 

Names Default to Here( 1 );

Test_DT = New Table( "Test",
 New Column( "No Color", set values( {2,2,2,2,2,2} ) ),
 New Column( "1-1", set values( {0,1,0,0} ) ),
 New Column( "2-1", set values( {0,0,0,1} ) ),
 New Column( "3-1", set values( {0,0,0,0,4} ) )
);

Col_List = Test_DT << Get Column Names( string );

For( i = Nitems( Col_List ), i > 0, i--,
 If( !Contains( Col_List[i], "-"),
  Remove from( Col_List, i )
 )
);

For( i = 1, i <= N Row( Test_DT ), i++,
 If( Column( Col_List )[i] >= 1,
  Column( Col_List ) << Color Cells( light orange, {i} )
 )
);

 

 

다시 : 목록을 통해 여러 열의 셀을 채색 할 수 없습니다

col_list를 반복해야합니다.

Names Default to Here( 1 );
Test_DT = New Table( "Test",
 New Column( "No Color", set values( {2,2,2,2,2,2} ) ),
 New Column( "1-1", set values( {0,1,0,0} ) ),
 New Column( "2-1", set values( {0,0,0,1} ) ),
 New Column( "3-1", set values( {0,0,0,0,4} ) )
);
Col_List = Test_DT << Get Column Names( string );
For( i = Nitems( Col_List ), i > 0, i--,
 If( !Contains( Col_List[i], "-"),
  Remove from( Col_List, i )
 )
);
For( i = 1, i <= N Row( Test_DT ), i++,
 for (k = 1, k <= nitems(col_list), k++,
  If ( Column( Col_List[k] )[i] >= 1,
   Column( Col_List[k] ) << Color Cells( light orange, {i} )
  );
 );
);

다시 : 목록을 통해 여러 열의 셀을 채색 할 수 없습니다

당신은 내가 너무 많은 일을 했어요.  셀 값을 참조하려고하는데 어떤 행을 나타내지 않았습니다.  작동하는 아래 코드를 살펴보십시오.  또한 내가 gt 1 인 경우 비교하고 있었고 원하는 결과의 경우> =이어야합니다.

Names Default To Here( 1 );

Test_DT = New Table( "Test",
 New Column( "No Color", set values( {2, 2, 2, 2, 2, 2} ) ),
 New Column( "1-1", set values( {0, 1, 0, 0} ) ),
 New Column( "2-1", set values( {0, 0, 0, 1} ) ),
 New Column( "3-1", set values( {0, 0, 0, 0, 4} ) )
);

Col_List = Test_DT << Get Column Names( string );

For( i = N Items( Col_List ), i > 0, i--,
 If( !Contains( Col_List[i], "-" ),
  Remove From( Col_List, i )
 )
);
For( ColNum = 1, ColNum <= N Items( Col_List ), ColNum++,
 For( i = 1, i <= N Row( Test_DT ), i++,
  If( (Column( Col_List[colNum] )[i]) >= 1,
   As Column( Col_List[ColNum] ) << Color Cells( light orange, {i} )
  );
 )
);

다시 : 목록을 통해 여러 열의 셀을 채색 할 수 없습니다

약간의 개선에 저항 할 수 없습니다.  모든 행을 열의 행렬로 수집하고 한 번에 색상을 설정합니다.  한 번에 한 행보다 효율적입니다.  사용했다 열로 에서 행을 얻는다 절.

Names Default to Here( 1 );

Test_DT = New Table( "Test",
 New Column( "No Color", set values( {2,2,2,2,2,2} ) ),
 New Column( "1-1", set values( {0,1,0,0} ) ),
 New Column( "2-1", set values( {0,0,0,1} ) ),
 New Column( "3-1", set values( {0,0,0,0,4} ) )
);

Col_List = Test_DT << Get Column Names( string );

For( i = Nitems( Col_List ), i > 0, i--,
 If( !Contains( Col_List[i], "-"),
  Remove from( Col_List, i )
 )
);

for (k = 1, k <= nitems(col_list), k++,
 one_col = Col_List[k];
 orange_rows = test_dt << get rows where(as column(test_dt, one_col) >= 1);
 if (nrows(orange_rows) > 0,
  Column(test_dt, one_col) << Color Cells( light orange, orange_rows );
 );
);

다시 : 목록을 통해 여러 열의 셀을 채색 할 수 없습니다훌륭하게 작동했습니다. 감사합니다!