248665_ja-JP

liliconcom

リストを介して複数の列のセルに色を付けることができません

特定の列名のリストを使用して、セル値ごとに色を変更するために複数の列をフォーマットしようとしていますが、コードはリストの最初の列のみをフォーマットします。

リスト内の残りの列もフォーマットするにはどうすればよいですか？

 

Names Default to Here( 1 );

Test_DT = New Table( "Test",
 New Column( "No Color", set values( {2,2,2,2,2,2} ) ),
 New Column( "1-1", set values( {0,1,0,0} ) ),
 New Column( "2-1", set values( {0,0,0,1} ) ),
 New Column( "3-1", set values( {0,0,0,0,4} ) )
);

Col_List = Test_DT << Get Column Names( string );

For( i = Nitems( Col_List ), i > 0, i--,
 If( !Contains( Col_List[i], "-"),
  Remove from( Col_List, i )
 )
);

For( i = 1, i <= N Row( Test_DT ), i++,
 If( Column( Col_List )[i] >= 1,
  Column( Col_List ) << Color Cells( light orange, {i} )
 )
);

 

 

再：リストを介して複数の列のセルを色付けできない

col_listもループする必要があります。

Names Default to Here( 1 );
Test_DT = New Table( "Test",
 New Column( "No Color", set values( {2,2,2,2,2,2} ) ),
 New Column( "1-1", set values( {0,1,0,0} ) ),
 New Column( "2-1", set values( {0,0,0,1} ) ),
 New Column( "3-1", set values( {0,0,0,0,4} ) )
);
Col_List = Test_DT << Get Column Names( string );
For( i = Nitems( Col_List ), i > 0, i--,
 If( !Contains( Col_List[i], "-"),
  Remove from( Col_List, i )
 )
);
For( i = 1, i <= N Row( Test_DT ), i++,
 for (k = 1, k <= nitems(col_list), k++,
  If ( Column( Col_List[k] )[i] >= 1,
   Column( Col_List[k] ) << Color Cells( light orange, {i} )
  );
 );
);

再：リストを介して複数の列のセルを色付けできない

あなたは私が何度もやりすぎたことをしました。  セル値を参照しようとしていますが、どの行を示しているのではありません。  動作している以下のコードを見てください。  また、あなたが私がgt 1であったかどうかを比較していました、そしてあなたが望む結果のために、それは> =であるべきです。

Names Default To Here( 1 );

Test_DT = New Table( "Test",
 New Column( "No Color", set values( {2, 2, 2, 2, 2, 2} ) ),
 New Column( "1-1", set values( {0, 1, 0, 0} ) ),
 New Column( "2-1", set values( {0, 0, 0, 1} ) ),
 New Column( "3-1", set values( {0, 0, 0, 0, 4} ) )
);

Col_List = Test_DT << Get Column Names( string );

For( i = N Items( Col_List ), i > 0, i--,
 If( !Contains( Col_List[i], "-" ),
  Remove From( Col_List, i )
 )
);
For( ColNum = 1, ColNum <= N Items( Col_List ), ColNum++,
 For( i = 1, i <= N Row( Test_DT ), i++,
  If( (Column( Col_List[colNum] )[i]) >= 1,
   As Column( Col_List[ColNum] ) << Color Cells( light orange, {i} )
  );
 )
);

再：リストを介して複数の列のセルを色付けできない

わずかな改善に抵抗できませんでした。  すべての行を列のマトリックスに収集し、すべての色を一度に設定します。  一度に1行よりも効率的です。  使用しなければならなかった列としての中に行を取得する句。

Names Default to Here( 1 );

Test_DT = New Table( "Test",
 New Column( "No Color", set values( {2,2,2,2,2,2} ) ),
 New Column( "1-1", set values( {0,1,0,0} ) ),
 New Column( "2-1", set values( {0,0,0,1} ) ),
 New Column( "3-1", set values( {0,0,0,0,4} ) )
);

Col_List = Test_DT << Get Column Names( string );

For( i = Nitems( Col_List ), i > 0, i--,
 If( !Contains( Col_List[i], "-"),
  Remove from( Col_List, i )
 )
);

for (k = 1, k <= nitems(col_list), k++,
 one_col = Col_List[k];
 orange_rows = test_dt << get rows where(as column(test_dt, one_col) >= 1);
 if (nrows(orange_rows) > 0,
  Column(test_dt, one_col) << Color Cells( light orange, orange_rows );
 );
);

再：リストを介して複数の列のセルを色付けできないそれは素晴らしく機能しました。ありがとうございました！