248665_de-DE

liliconcom

Zellen in mehreren Spalten können nicht über Liste eingefärbt werden

Ich versuche, mehrere Spalten zu formatieren, um die Farbe nach Zellenwert mithilfe einer Liste bestimmter Spaltennamen zu ändern, aber mein Code formatiert nur die erste Spalte in der Liste.

Wie kann ich auch den Rest der Spalten in der Liste formatieren?

 

Names Default to Here( 1 );

Test_DT = New Table( "Test",
 New Column( "No Color", set values( {2,2,2,2,2,2} ) ),
 New Column( "1-1", set values( {0,1,0,0} ) ),
 New Column( "2-1", set values( {0,0,0,1} ) ),
 New Column( "3-1", set values( {0,0,0,0,4} ) )
);

Col_List = Test_DT << Get Column Names( string );

For( i = Nitems( Col_List ), i > 0, i--,
 If( !Contains( Col_List[i], "-"),
  Remove from( Col_List, i )
 )
);

For( i = 1, i <= N Row( Test_DT ), i++,
 If( Column( Col_List )[i] >= 1,
  Column( Col_List ) << Color Cells( light orange, {i} )
 )
);

 

 

Betreff: Zellen in mehreren Spalten können nicht über Liste eingefärbt werden

Sie müssen auch col_list durchlaufen.

Names Default to Here( 1 );
Test_DT = New Table( "Test",
 New Column( "No Color", set values( {2,2,2,2,2,2} ) ),
 New Column( "1-1", set values( {0,1,0,0} ) ),
 New Column( "2-1", set values( {0,0,0,1} ) ),
 New Column( "3-1", set values( {0,0,0,0,4} ) )
);
Col_List = Test_DT << Get Column Names( string );
For( i = Nitems( Col_List ), i > 0, i--,
 If( !Contains( Col_List[i], "-"),
  Remove from( Col_List, i )
 )
);
For( i = 1, i <= N Row( Test_DT ), i++,
 for (k = 1, k <= nitems(col_list), k++,
  If ( Column( Col_List[k] )[i] >= 1,
   Column( Col_List[k] ) << Color Cells( light orange, {i} )
  );
 );
);

Betreff: Zellen in mehreren Spalten können nicht über Liste eingefärbt werden

Du hast etwas getan, was ich zu oft getan habe.  Sie versuchen, auf einen Zellenwert zu verweisen, geben jedoch nicht an, welche Zeile verwendet wird.  Schauen Sie sich den folgenden Code an, der funktioniert.  Außerdem haben Sie verglichen, ob ich GT 1 war, und für die gewünschten Ergebnisse sollte es> = sein.

Names Default To Here( 1 );

Test_DT = New Table( "Test",
 New Column( "No Color", set values( {2, 2, 2, 2, 2, 2} ) ),
 New Column( "1-1", set values( {0, 1, 0, 0} ) ),
 New Column( "2-1", set values( {0, 0, 0, 1} ) ),
 New Column( "3-1", set values( {0, 0, 0, 0, 4} ) )
);

Col_List = Test_DT << Get Column Names( string );

For( i = N Items( Col_List ), i > 0, i--,
 If( !Contains( Col_List[i], "-" ),
  Remove From( Col_List, i )
 )
);
For( ColNum = 1, ColNum <= N Items( Col_List ), ColNum++,
 For( i = 1, i <= N Row( Test_DT ), i++,
  If( (Column( Col_List[colNum] )[i]) >= 1,
   As Column( Col_List[ColNum] ) << Color Cells( light orange, {i} )
  );
 )
);

Betreff: Zellen in mehreren Spalten können nicht über Liste eingefärbt werden

Konnte einer leichten Verbesserung nicht widerstehen.  Sammelt alle Zeilen in einer Matrix für eine Spalte und legt alle Farben gleichzeitig fest.  Effizienter als eine Zeile gleichzeitig.  Musste verwenden als Spalte in dem Zeilen bekommen wo Klausel.

Names Default to Here( 1 );

Test_DT = New Table( "Test",
 New Column( "No Color", set values( {2,2,2,2,2,2} ) ),
 New Column( "1-1", set values( {0,1,0,0} ) ),
 New Column( "2-1", set values( {0,0,0,1} ) ),
 New Column( "3-1", set values( {0,0,0,0,4} ) )
);

Col_List = Test_DT << Get Column Names( string );

For( i = Nitems( Col_List ), i > 0, i--,
 If( !Contains( Col_List[i], "-"),
  Remove from( Col_List, i )
 )
);

for (k = 1, k <= nitems(col_list), k++,
 one_col = Col_List[k];
 orange_rows = test_dt << get rows where(as column(test_dt, one_col) >= 1);
 if (nrows(orange_rows) > 0,
  Column(test_dt, one_col) << Color Cells( light orange, orange_rows );
 );
);

Betreff: Zellen in mehreren Spalten können nicht über Liste eingefärbt werdenDas hat wunderbar funktioniert. Vielen Dank!