API key to publish to JMP Live/Public

benfrancis

I remember in a recent JMP Live call there was explanation that we needed to include an API key in our JSL to publish to JMP Live/Public. Does anyone have details of this? I've gone through 10 useful tips for automating the publishing of JMP Live reports but the API key is not included in these instructions yet. 

 

Also, is there anyway to direct the publish to JMP Live or Public? Would seem that the destination is hardwired into the settings for JSL.

 

 

Ryan_Gilmore

Here's the code that I use for publishing to JMP Live that includes the API key parameter. The value given to the URL parameter is used to direct the publish to the appropriate JMP Live instance.

 

Names Default To Here( 1 );

Include( "JMPLiveCredentials.jsl" );

JMPLive = New Namespace(
	"JMPLive"
);

JMPLive:Initialize() = Function( {},
	{},
	JMPLive:key = Credentials:key;
	JMPLive:server = Credentials:server;
);

JMPLive:Publish Report = Function( {web_report, package_id = Empty()}, 

	publishExpr = Expr(
		Publish(
			Prompt( Never ),
			URL( JMPLive:server ),
			API key( JMPLive:key ),
			Public( 0 ),
			Publish Data( 1 )
		)
	);
	
	If( !Is Empty( package_id ),
		Insert Into( publishExpr, Expr( Replace( package_id, Prompt( Never ) ) ) )
	);
	
	Eval( Substitute( Expr( web_report << publishMessage ), Expr( publishMessage ), Name Expr( publishExpr ) ) );
);

JMPLive:Initialize();

 

then do something similar to the following:

 

report = New Web Report();
	
report << Add Report(
	Community_Graphs:Create Graph of Actions(),
	Title( "JMP Community - Actions" ),
	Description( "Displays the actions taken by users" )
);

// To replace a report
JMPLive:Publish Report( report, "zsa8Hypq021n" );

// To create a new report
JMPLive:Publish Report( report );

Hope that helps.

JMPLive.jsl