248233_ko-KR

liliconcom

칼럼 스위처 및 트라이 기능

안녕하세요,

컬럼 스위처 스크립트에서 try 기능을 사용할 수 있습니까? 나는 선택된 몇 개의 열을 그래프에 추가하는 열 전환기를 추가하는 스크립트를 만들고 있습니다. 그러나 때로는 열이 없어서 스크립트가 중지됩니다. 따라서 (열 전환기의 모든 열을 원하지 않기 때문에) 각 관련 열에 대해 try 함수를 사용하려고하지만 작동시킬 수 없습니다. 

 

dt << 컬럼 스위처 (
try ((: RER), throw ( "RER이 존재하지 않습니다")),
try ((: VO2), throw ( "VO2 존재하지 않음")),
try (: Name ( "음료 [ml]"), throw ( "음료 [ml]가 존재하지 않습니다"))
);

 

가능합니까 아니면 더 좋은 방법이 있습니까?

브릴리

 

다시 : 열 스위처 및 시도 기능

여기 내가 어떻게 할 것인가

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );


// set desired list of columns to be in column switcher
desiredColList = {"Height", "Weight", "Zippy"};

// remove from list, columns that are not available
For( i = N Items( desiredColList ), i >= 1, i--,
 If( Try( Column( dt, desiredColList[i] ) << get name, "" ) == "",
  Remove From( desiredColList, i, 1 )
 )
);

// If columns are available, run the platform
If( N Items( desiredColList ) > 0,
 ow = oneway( x( :age ), y( :height ) );
 ow << Column Switcher( :height, desiredColList );
);

다시 : 열 스위처 및 시도 기능

메시지 외부에서 Try () 함수를 사용합니다. 조건부로 메시지를 작성하십시오. 이처럼 :

 

Names Default to Here( 1 );

dt = Open( "$SAMPLE_DATA/Fitness.jmp" );

gb = dt << Graph Builder(
 Size( 532, 456 ),
 Show Control Panel( 0 ),
 Show Legend( 0 ),
 Variables( X( :Age ), Y( :Oxy ) ),
 Elements( Points( X, Y, Legend( 3 ) ) )
);

alt cols = List();
Try(
 Insert Into( alt cols, Column( dt, "Age" ) )
);
Try(
 Insert Into( alt cols, Column( dt, "Weight" ) )
);
Try(
 Insert Into( alt cols, Column( dt, "Runtime" ) )
);

col switcher expr = Expr( Column Switcher( :age ) );
Insert Into( col switcher expr, alt cols );

Eval(
 Insert(
  Expr( Send( gb ) ),
  Name Expr( col switcher expr )
 )
);