248233_ja-JP

liliconcom

列切り替えと試行機能

こんにちは、

列切り替えスクリプトでtry関数を使用することはできますか？いくつかの選択した列の列スイッチャーをグラフに追加して、正常に動作するスクリプトを作成しています。ただし、スクリプトが停止する列が欠落する場合があります。したがって、関連する各列に対してtry関数を使用しようとしています（列スイッチャーにすべての列が必要なわけではないため）が、機能させることはできません。 

 

dt << Column Switcher（
try（（：RER）、throw（ "RER does not exist"））、
try（（：VO2）、throw（ "VO2 does not exist"））、
try（：Name（ "Drink- [ml]"）、throw（ "Drink- [ml]は存在しません"））
）;

 

それは可能ですか、これを行うより良い方法はありますか？

Brジュリー

 

再：列スイッチャー＆試用機能

ここに私がそれをする方法があります

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );


// set desired list of columns to be in column switcher
desiredColList = {"Height", "Weight", "Zippy"};

// remove from list, columns that are not available
For( i = N Items( desiredColList ), i >= 1, i--,
 If( Try( Column( dt, desiredColList[i] ) << get name, "" ) == "",
  Remove From( desiredColList, i, 1 )
 )
);

// If columns are available, run the platform
If( N Items( desiredColList ) > 0,
 ow = oneway( x( :age ), y( :height ) );
 ow << Column Switcher( :height, desiredColList );
);

再：列スイッチャー＆試用機能

メッセージの外部でTry（）関数を使用します。メッセージを条件付きで作成します。このような：

 

Names Default to Here( 1 );

dt = Open( "$SAMPLE_DATA/Fitness.jmp" );

gb = dt << Graph Builder(
 Size( 532, 456 ),
 Show Control Panel( 0 ),
 Show Legend( 0 ),
 Variables( X( :Age ), Y( :Oxy ) ),
 Elements( Points( X, Y, Legend( 3 ) ) )
);

alt cols = List();
Try(
 Insert Into( alt cols, Column( dt, "Age" ) )
);
Try(
 Insert Into( alt cols, Column( dt, "Weight" ) )
);
Try(
 Insert Into( alt cols, Column( dt, "Runtime" ) )
);

col switcher expr = Expr( Column Switcher( :age ) );
Insert Into( col switcher expr, alt cols );

Eval(
 Insert(
  Expr( Send( gb ) ),
  Name Expr( col switcher expr )
 )
);