248233_de-DE

liliconcom

Spaltenumschalter & Try-Funktion

Hallo,

Ist es möglich, die try-Funktion in einem Spaltenumschaltskript zu verwenden? Ich erstelle ein Skript, in dem ich einen Spaltenumschalter für einige ausgewählte Spalten zu einem Diagramm hinzufüge, das einwandfrei funktioniert. Manchmal fehlt jedoch eine Spalte, wodurch das Skript gestoppt wird. Daher versuche ich, die try-Funktion für jede der relevanten Spalten zu verwenden (da ich nicht alle Spalten im Spaltenumschalter haben möchte), aber ich kann sie nicht zum Laufen bringen. 

 

dt << Column Switcher (
try ((: RER), throw ("RER existiert nicht")),
try ((: VO2), throw ("VO2 existiert nicht")),
try (: Name ("Drink- [ml]"), throw ("Drink- [ml] existiert nicht"))
);

 

Ist es möglich oder gibt es einen besseren Weg, dies zu tun?

Br Julie

 

Betreff: Column Switcher & Try-Funktion

Hier ist, wie ich es machen würde

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );


// set desired list of columns to be in column switcher
desiredColList = {"Height", "Weight", "Zippy"};

// remove from list, columns that are not available
For( i = N Items( desiredColList ), i >= 1, i--,
 If( Try( Column( dt, desiredColList[i] ) << get name, "" ) == "",
  Remove From( desiredColList, i, 1 )
 )
);

// If columns are available, run the platform
If( N Items( desiredColList ) > 0,
 ow = oneway( x( :age ), y( :height ) );
 ow << Column Switcher( :height, desiredColList );
);

Betreff: Column Switcher & Try-Funktion

Ich würde die Try () - Funktion außerhalb der Nachricht verwenden. Erstellen Sie die Nachricht unter bestimmten Bedingungen. So was:

 

Names Default to Here( 1 );

dt = Open( "$SAMPLE_DATA/Fitness.jmp" );

gb = dt << Graph Builder(
 Size( 532, 456 ),
 Show Control Panel( 0 ),
 Show Legend( 0 ),
 Variables( X( :Age ), Y( :Oxy ) ),
 Elements( Points( X, Y, Legend( 3 ) ) )
);

alt cols = List();
Try(
 Insert Into( alt cols, Column( dt, "Age" ) )
);
Try(
 Insert Into( alt cols, Column( dt, "Weight" ) )
);
Try(
 Insert Into( alt cols, Column( dt, "Runtime" ) )
);

col switcher expr = Expr( Column Switcher( :age ) );
Insert Into( col switcher expr, alt cols );

Eval(
 Insert(
  Expr( Send( gb ) ),
  Name Expr( col switcher expr )
 )
);