246607_de-DE

liliconcom

Hierarchisches Anzeigefeld

Hallo,

Was ist der beste Weg, die hierarchische Gruppe von Boxen mit JSL zu erstellen?

Ich möchte zum Beispiel eine Verteilung für jedes Geschlecht und jedes Alter erstellen (Big Class.jmp) und diese dann wie im Datei-Explorer anordnen.

(Siehe beigefügten Screenshot)

Ich hoffe, meine Frage ist klar

 

Danke

Tom.

 

 

 

 

 

Betreff: Hierarchisches Anzeigefeld

Was ist der beste Weg, dies mit Tab-Boxen zu tun?

@Mark_Bailey

Danke!

Betreff: Hierarchisches Anzeigefeld

Craige,

Cool......

Betreff: Hierarchisches Anzeigefeld

Es gibt auch ein Hierarchiefeld, hauptsächlich für Ishikawa Fischgrätendiagramme, jedoch mit 3 Darstellungsstilen.

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

window = New Window( "Hierarch", vlb = Hier Box( Text Box( "Big Class" ) ) );

Summarize( sex group = By( :sex ) );
Summarize( age group = By( :age ) );

For( isex = 1, isex <= N Items( sex group ), isex++,
 outline = Hier Box( Text Box( "Sex = " || sex group[isex] ) );
 For( iage = 1, iage <= N Items( age group ), iage++,
  Eval(
   Eval Expr(
    outline << Append(
     Hier Box(
      Text Box( "Age = " || age group[iage] ),
      Button Box( "Sex is " || sex group[isex] || " and Age is " || age group[iage],
       // the button runs a script, use eval(evalexpr(...expr(xxx)))
       // to capture a value of a variable that was only available 
       // while the display box tree was being constructed...
       Print( Expr( age group[iage] ), Expr( sex group[isex] ) )
      )
     )
    )
   )
  );
  
 );
 vlb << Append( outline );
);
vlb << changetype( "fishbone" );
Wait( 1 );
vlb << changetype( "hierarchy" );
Wait( 1 );
vlb << changetype( "nested" );

three styles of hier box presentationDrei Arten der Hier-Box-Präsentation

Ich habe das Textfeld durch das Schaltflächenfeld ersetzt. Wenn Sie auf eine davon klicken, heißt es:

„13“
"F"

 

Betreff: Hierarchisches Anzeigefeld

Eine Baumbox mit Baumknoten könnte Ihren Wünschen näher kommen.

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
Summarize( sex group = By( :sex ) );
Summarize( age group = By( :age ) );
gender_tree = {};
For( isex = 1, isex <= N Items( sex group ), isex++,
 gnode = tree node( "Gender - " || sex group[isex] );
 For( iage = 1, iage <= N Items( age group), iage++,
  age_node = tree node(age group[iage]);
  gnode << append(age_node);
 );
 insert into(gender_tree, gnode);
);

nw = New Window( "Hierarchy Tree", 
 gtree = tree box(gender_tree, size(300, 300),
  set max size(600, 600),
  set autostretching(1, 1)
 )
);

root_list = gtree << get roots;
for (i = 1, i <= nitems(root_list), i++,
 gtree << expand(root_list[i]);
);

Betreff: Hierarchisches Anzeigefeld

 

Nachdem ich diese Antwort gepostet hatte, habe ich den Code erneut ausprobiert und es hat problemlos funktioniert!Tut mir leid, Mark!

 

Mark, ich musste Ihre Schleifenvariablen ändern, weil sie mit den Spaltennamen in Big Class identisch sind.

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

window = New Window( "Hierarch", vlb = V List Box() );

Summarize( sex group = By( :sex ) );
Summarize( age group = By( :age ) );

For( isex = 1, isex <= N Items( sex group ), isex++,
 outline = Outline Box( "Sex = " || sex group[isex] );
 For( iage = 1, iage <= N Items( age group), iage++,
  outline << Append(
   Outline Box( "Age = " || age group[iage],
    Text Box( "Sex is " || sex group[isex] || " and Age is " || age group[iage] )
   )
  );
  Show( isex, iage );
 );
 vlb << Append( outline );
);

 

Betreff: Hierarchisches Anzeigefeld

Dieses Beispiel veranschaulicht einen Ansatz:

 

Names Default to Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

window = New Window( "Hierarch", vlb = V List Box() );

Summarize( sex group = By( :sex ) );
Summarize( age group = By( :age ) );

For( sex = 1, sex <= N Items( sex group ), sex++,
 outline = Outline Box( "Sex = " || sex group[sex] );
 For( age = 1, age <= N Items( age group), age++,
  outline << Append(
   Outline Box( "Age = " || age group[age],
    Text Box( "Sex is " || sex group[sex] || " and Age is " || age group[age] )
   )
  );
  Show( sex, age );
 );
 vlb << Append( outline );
);