246607_it-IT

liliconcom

casella di visualizzazione gerarchica

Ciao,

Qual è il modo migliore per creare il gruppo gerarchico di scatole con JSL?

Ad esempio, voglio creare una distribuzione per ogni genere e ogni età (Big Class.jmp) e poi voglio organizzarli come in Esplora file.

(Si prega di vedere uno screenshot in allegato)

Spero che la mia domanda sia chiara

 

Grazie

Tom.

 

 

 

 

 

Re: casella di visualizzazione gerarchica

Qual è il modo migliore per farlo con le caselle Tab?

@Mark_Bailey

Grazie!

Re: casella di visualizzazione gerarchica

Craig,

Freddo......

Re: casella di visualizzazione gerarchica

C'è anche una casella della gerarchia, principalmente per Ishikawa Diagrammi a lisca di pesce, ma con 3 stili di presentazione.

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

window = New Window( "Hierarch", vlb = Hier Box( Text Box( "Big Class" ) ) );

Summarize( sex group = By( :sex ) );
Summarize( age group = By( :age ) );

For( isex = 1, isex <= N Items( sex group ), isex++,
 outline = Hier Box( Text Box( "Sex = " || sex group[isex] ) );
 For( iage = 1, iage <= N Items( age group ), iage++,
  Eval(
   Eval Expr(
    outline << Append(
     Hier Box(
      Text Box( "Age = " || age group[iage] ),
      Button Box( "Sex is " || sex group[isex] || " and Age is " || age group[iage],
       // the button runs a script, use eval(evalexpr(...expr(xxx)))
       // to capture a value of a variable that was only available 
       // while the display box tree was being constructed...
       Print( Expr( age group[iage] ), Expr( sex group[isex] ) )
      )
     )
    )
   )
  );
  
 );
 vlb << Append( outline );
);
vlb << changetype( "fishbone" );
Wait( 1 );
vlb << changetype( "hierarchy" );
Wait( 1 );
vlb << changetype( "nested" );

three styles of hier box presentationtre stili di presentazione hier box

Ho sostituito la casella del pulsante per la casella di testo. Facendo clic su uno di essi si dice:

"13"
"F"

 

Re: casella di visualizzazione gerarchica

Una scatola ad albero contenente nodi ad albero potrebbe essere più vicina a ciò che desideri.

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
Summarize( sex group = By( :sex ) );
Summarize( age group = By( :age ) );
gender_tree = {};
For( isex = 1, isex <= N Items( sex group ), isex++,
 gnode = tree node( "Gender - " || sex group[isex] );
 For( iage = 1, iage <= N Items( age group), iage++,
  age_node = tree node(age group[iage]);
  gnode << append(age_node);
 );
 insert into(gender_tree, gnode);
);

nw = New Window( "Hierarchy Tree", 
 gtree = tree box(gender_tree, size(300, 300),
  set max size(600, 600),
  set autostretching(1, 1)
 )
);

root_list = gtree << get roots;
for (i = 1, i <= nitems(root_list), i++,
 gtree << expand(root_list[i]);
);

Re: casella di visualizzazione gerarchica

 

Dopo aver pubblicato questa risposta, ho provato di nuovo il codice e ha funzionato senza problemi!Scusa Marco!

 

Mark ho dovuto cambiare le tue variabili di loop perché sono le stesse dei nomi delle colonne in Big Class.

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

window = New Window( "Hierarch", vlb = V List Box() );

Summarize( sex group = By( :sex ) );
Summarize( age group = By( :age ) );

For( isex = 1, isex <= N Items( sex group ), isex++,
 outline = Outline Box( "Sex = " || sex group[isex] );
 For( iage = 1, iage <= N Items( age group), iage++,
  outline << Append(
   Outline Box( "Age = " || age group[iage],
    Text Box( "Sex is " || sex group[isex] || " and Age is " || age group[iage] )
   )
  );
  Show( isex, iage );
 );
 vlb << Append( outline );
);

 

Re: casella di visualizzazione gerarchica

Questo esempio illustra un approccio:

 

Names Default to Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

window = New Window( "Hierarch", vlb = V List Box() );

Summarize( sex group = By( :sex ) );
Summarize( age group = By( :age ) );

For( sex = 1, sex <= N Items( sex group ), sex++,
 outline = Outline Box( "Sex = " || sex group[sex] );
 For( age = 1, age <= N Items( age group), age++,
  outline << Append(
   Outline Box( "Age = " || age group[age],
    Text Box( "Sex is " || sex group[sex] || " and Age is " || age group[age] )
   )
  );
  Show( sex, age );
 );
 vlb << Append( outline );
);