246607_fr-FR

liliconcom

boîte d'affichage hiérarchique

Salut,

Quelle est la meilleure façon de créer le groupe hiérarchique de boîtes avec JSL ?

Par exemple, je veux créer une distribution pour chaque sexe et chaque âge (Big Class.jmp), puis je veux les organiser comme dans l'explorateur de fichiers.

(Veuillez voir ci-joint une capture d'écran)

J'espère que ma question est claire

 

Merci

À M.

 

 

 

 

 

Re : boîte d'affichage hiérarchique

Quelle est la meilleure façon de le faire avec les boîtes à onglets ?

@Mark_Bailey

Merci!

Re : boîte d'affichage hiérarchique

Craige,

Cool......

Re : boîte d'affichage hiérarchique

Il existe également une boîte de hiérarchie, principalement pour Ishikawa Diagrammes en arête de poisson, mais avec 3 styles de présentation.

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

window = New Window( "Hierarch", vlb = Hier Box( Text Box( "Big Class" ) ) );

Summarize( sex group = By( :sex ) );
Summarize( age group = By( :age ) );

For( isex = 1, isex <= N Items( sex group ), isex++,
 outline = Hier Box( Text Box( "Sex = " || sex group[isex] ) );
 For( iage = 1, iage <= N Items( age group ), iage++,
  Eval(
   Eval Expr(
    outline << Append(
     Hier Box(
      Text Box( "Age = " || age group[iage] ),
      Button Box( "Sex is " || sex group[isex] || " and Age is " || age group[iage],
       // the button runs a script, use eval(evalexpr(...expr(xxx)))
       // to capture a value of a variable that was only available 
       // while the display box tree was being constructed...
       Print( Expr( age group[iage] ), Expr( sex group[isex] ) )
      )
     )
    )
   )
  );
  
 );
 vlb << Append( outline );
);
vlb << changetype( "fishbone" );
Wait( 1 );
vlb << changetype( "hierarchy" );
Wait( 1 );
vlb << changetype( "nested" );

three styles of hier box presentationtrois styles de présentation de boîte hier

J'ai remplacé la boîte à boutons par la zone de texte. Cliquer sur l'un d'eux dit:

"13"
"F"

 

Re : boîte d'affichage hiérarchique

Une boîte d'arbre contenant des nœuds d'arbre peut être plus proche de ce que vous voulez.

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
Summarize( sex group = By( :sex ) );
Summarize( age group = By( :age ) );
gender_tree = {};
For( isex = 1, isex <= N Items( sex group ), isex++,
 gnode = tree node( "Gender - " || sex group[isex] );
 For( iage = 1, iage <= N Items( age group), iage++,
  age_node = tree node(age group[iage]);
  gnode << append(age_node);
 );
 insert into(gender_tree, gnode);
);

nw = New Window( "Hierarchy Tree", 
 gtree = tree box(gender_tree, size(300, 300),
  set max size(600, 600),
  set autostretching(1, 1)
 )
);

root_list = gtree << get roots;
for (i = 1, i <= nitems(root_list), i++,
 gtree << expand(root_list[i]);
);

Re : boîte d'affichage hiérarchique

 

Après avoir posté cette réponse, j'ai réessayé le code et cela a fonctionné sans problème!Désolé Marc !

 

Mark J'ai dû changer vos variables en boucle car elles sont identiques aux noms de colonne dans Big Class.

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

window = New Window( "Hierarch", vlb = V List Box() );

Summarize( sex group = By( :sex ) );
Summarize( age group = By( :age ) );

For( isex = 1, isex <= N Items( sex group ), isex++,
 outline = Outline Box( "Sex = " || sex group[isex] );
 For( iage = 1, iage <= N Items( age group), iage++,
  outline << Append(
   Outline Box( "Age = " || age group[iage],
    Text Box( "Sex is " || sex group[isex] || " and Age is " || age group[iage] )
   )
  );
  Show( isex, iage );
 );
 vlb << Append( outline );
);

 

Re : boîte d'affichage hiérarchique

Cet exemple illustre une approche :

 

Names Default to Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

window = New Window( "Hierarch", vlb = V List Box() );

Summarize( sex group = By( :sex ) );
Summarize( age group = By( :age ) );

For( sex = 1, sex <= N Items( sex group ), sex++,
 outline = Outline Box( "Sex = " || sex group[sex] );
 For( age = 1, age <= N Items( age group), age++,
  outline << Append(
   Outline Box( "Age = " || age group[age],
    Text Box( "Sex is " || sex group[sex] || " and Age is " || age group[age] )
   )
  );
  Show( sex, age );
 );
 vlb << Append( outline );
);